批处理命令入门
批处理教程
我最近根据网络搜集与自己的整理形成以下的文章,现与大家共享:
第一节 常用批处理内部命令简介
批处理本质:是一堆DOS命令按一定顺序排列而形成的集合。批处理的作用就是自动的连续执行多条命令,批处理,也称为批处理脚本,英文译为BATCH。批处理有一个很鲜明的特点:使用方便、灵活,功能强大,自动化程度高。扩展名是bat(在nt/2000/xp/2003下也可以是cmd)的文件就是批处理文件。一个良好的习惯是在硬盘上建立一个bat或者batch目录(例如C:/BATCH),然后将所有你编写的批处理文件放到该目录中。
首先,批处理文件是一个文本文件,文件的每一行都是一条DOS命令。
其次,批处理文件是一种简单的程序,通过(if)和制语句(goto)来控制命令运行的流程。
第三,编写好的批处理文件都相当于一个DOS的外部命令,可以在任何位置调用运行。
第四,在DOS和Win9x/Me系统下,C:/AUTOEXEC.BAT是启动计算机自动运行的。
介绍命令
1、REM和 :: REM为注释命令,可以回显,::不回显,简洁有效亦可加快运行速度。第一、任何以冒号开头的字符行,在批处理中都被视作标号,而直接忽略其后的所有内容。
有效标号:冒号后紧跟一个以字母数字开头的字符串,goto语句可以识别。
无效标号:冒号后紧跟一个非字母数字的一个特殊符号,goto无法识别的标号,可以起到注释作用,所以”::”常被用作注释符号,其实:+也可起注释作用。
第二、rem在某些场合下将比::更为适用;另外, rem 可以用于config.sys 文件中。
2、ECHO 和 @
@Echo off
Echo hello
Pause
运行显示:hello
3、PAUSE Echo 其他提示语 & pause > nul(Echo 其他提示语 & pause >>nul效果一样)
或者写成以下形式其功能也一样(两行):
Echo 其他提示语
pause >(>>) nul
4、errorlevel
程序返回码echo %errorlevel%命令行格式查看返回码判断命令是否成,成功返回“0”
5、title 设置cmd窗口的标题 : title 新标题
6、COLOR 设置默认的控制台前景和背景颜色。
COLOR [attr] 第一个为背景,第二个则为前景。
7、mode 配置系统设备 help mode >a.txt
8、GOTO 和 :
if {%1}=={} goto noparms;if "%2"=="" goto noparms
@echo off
:start
set /a var+=1
echo %var%
if %var% leq 3 GOTO start
pause
9、find在文件中搜索字符串。如果没有指定路径FIND 将搜索键入的或者由另一命令产生的文字。 Find常和type命令结合使用
Type [drive:][path]filename | find "string" [>tmpfile] #挑选包含string的行
Type [drive:][path]filename | find /v "string" #剔除文件中包含string的行
Type [drive:][path]filename | find /c #显示文件行数
10、start 命令:批处理中调用外部程序的命令;如果直接运行外部程序则必须等外部程序完成后才继续执行剩下的指令 start explorer d:/ 调用图形界面打开D盘(cd d:/)
11、assoc 和 ftype 文件关联
assoc 设置'文件扩展名'关联,关联到'文件类型' ftype 设置'文件类型'关联,关联到'执行程序和参数' 当你双击一个.txt文件时,windows并不是根据.txt直接判断用 notepad.exe 打开而是先判断.txt属于txtfile '文件类型'再调用txtfile 关联的命令行 txtfile=%SystemRoot%/system32/NOTEPAD.EXE %1可以在"文件夹选项"→"文件类型"里修改这2种关联
assoc 显示所有'文件扩展名'关联;assoc .txt [#]显示.txt代表的'文件类型。
ftype 显示所有'文件类型'关联;ftype exefile [#]显示exefile类型关联的命令行
assoc .txt=Word.Document.8可以看到.txt文件的图标都变了
assoc .txt=txtfile 恢复.txt的正确关联;ftype exefile="%1" %*恢复 exefile 的正确关联
如果该关联已经被破坏,可以运行 command.com ,再输入这条命令
12、pushd 和 popd 切换当前目录
@echo off
c: & cd/ & md mp3 ::在 C:/ 建立 mp3 文件夹
md d:/mp4 ::在 D:/ 建立 mp4 文件夹
cd d d:/mp4 ::更改当前目录为 d:/mp4
pushd c:/mp3 ::保存当前目录,并切换当前目录为 c:/mp3
popd ::恢复当前目录为刚才保存的 d:/mp4
pause13、CALL
CALL [drive:][path]filename [batch-parameters]调用的其它批处理程序。filename 参数必须具有 .bat 或 .cmd 扩展名。CALL :label arguments调用本文件内命令段,相当于子程序。被调用的命令段以标签:label开头以命令goto :eof结尾。
批脚本里的%* 指出所有的参数(如 %1 %2 %3 %4 %5 ...)
参数扩充时不理会参数所代表的文件是否真实存在,均以当前目录进行扩展
@echo off
Echo 产生一个临时文件 > tmp.txt
Rem 下行先保存当前目录,再将c:/windows设为当前目录
pushd c:/windows
Call :sub tmp.txt
Rem 下行恢复前次的当前目录
Popd
Call :sub tmp.txt
pause
Del tmp.txt
:sub
Echo 删除引号: %~1
Echo 扩充到路径: %~f1
Echo 扩充到一个驱动器号: %~d1
Echo 扩充到一个路径: %~p1
Echo 扩充到一个文件名: %~n1
Echo 扩充到一个文件扩展名: %~x1
Echo 扩充的路径指含有短名: %~s1
Echo 扩充到文件属性: %~a1
Echo 扩充到文件的日期/时间: %~t1
Echo 扩充到文件的大小: %~z1
Echo 扩展到驱动器号和路径:%~dp1
Echo 扩展到文件名和扩展名:%~nx1
Echo 扩展到类似 DIR 的输出行:%~ftza1
Echo.
Goto :eof
14、shift 更改批处理文件中可替换参数的位置。
SHIFT [/n]:命令从第 n 个参数开始移位;n 介于零和八之间。例如:
SHIFT /2会将 %3 移位到 %2,将 %4 移位到 %3,等等;并且不影响 %0 和 %1。
15、IF
(1) IF [NOT] ERRORLEVEL number command
IF ERRORLEVEL执行命令后由IF ERRORLEVEL 来判断命令的返回值。Number的数字范围0~255,判断时值的排列顺序应该由大到小。返回的值大于等于指定的值时,条件成立。
例:
@echo off
dir c:
rem 退出代码为>=1就跳至标题1处执行,>=0就跳至标题0处执行
IF ERRORLEVEL 1 goto 1
IF ERRORLEVEL 0 goto 0
Rem 上面的两行不可交换位置,否则失败了也显示成功。
:0
echo 命令执行成功!
Rem 程序执行完毕跳至标题exit处退出
goto exit
:1
echo 命令执行失败!
Rem 程序执行完毕跳至标题exit处退出
goto exit
:exit
pause
(2) IF [NOT] string1==string2 command
string1和string2都为字符的数据。(绝对相等的意思)条件相等后即执行后面的command检测当前变量的值做出判断,为防止字符串中有空格,可用以下格式
if [NOT] {string1}=={string2} command;
if [NOT] [string1]==[string2] command if [NOT] “string1”==“string2”command这种写法实际上将括号或引号当成字符串的一部分了
(3) IF [NOT] EXIST filename command
EXIST filename为文件或目录存在的意思
echo off
IF EXIST autoexec.bat echo 文件存在!
IF not EXIST autoexec.bat echo 文件不存在!
16、setlocal 与 变量延迟 setlocal enabledelayedexpansion
例1:
@echo off
set a=4
set a=5 & echo %a%
pause
结果:4
第二节 常用特殊符号
管道命令(优先级)>重定向命令>组合命令
1、@ 命令行回显屏蔽符;2、% 批处理变量引导符;3、> 重定向符;4、>> 重定向符;5、<、>&、<& 重定向符;6、| 命令管道符;7、^ 转义字符;8、& 组合命令;9、&& 组合命令;10、|| 组合命令;11、"" 字符串界定符;12、, 逗号;13、; 分号;14、() 括号;15、! 感叹号(变量延迟的启动语句是“setlocal enabledelayedexpansion”)
16、批处理中可能会见到的其它特殊标记符:CR(0D)命令行结束符;Escape(1B) ANSI转义字符引导符;Space(20) 常用的参数界定符 Tab(09) ; = 不常用的参数界定符;+ COPY命令文件连接符;* ? 文件通配符;/ 参数开关引导符;批处理标签引导符。
1、@ 命令行回显屏蔽符
2、% 批处理变量引导符:它只是批处理中的参数而已,引用变量用%var%,调用程序外部参数用%1至%9等等,%0 %1 %2 %3 %4 %5 %6 %7 %8 %9 %*为命令行传递给批处理的参数%0 批处理文件本身,包括完整的路径和扩展名;%1 第一个参数;%9 第九个参数;%* 从第一个参数开始的所有参数;参数%0具有特殊的功能,可以调用批处理自身,以达到批处理本身循环的目的,也可以复制文件自身等等。
例:最简单的复制文件自身的方法 copy %0 d:/wind.bat
3、>重定向符
4、>>重定向符
5、<、>&、<&重定向符”<”输入重定向命令从文件中读取命令输入,而不是从键盘中读入。
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt
>& 将一个句柄的输出写入到另一个句柄的输入中;<& 从一个句柄读取输入并将其写入到另一个句柄输出中。常用句柄:0、1、2,未定义句柄:3—9
1>nul 表示禁止输出正确的信息;2>nul 表示禁止输出错误信息。
其中的1与2都是代表某个数据流输入输出的地址(NT CMD 称之为句柄,MSDOS称之为设备)。
句柄0:标准输入stdin,键盘输入;句柄1:标准输出stdout,输出到命令提示符窗口(console,代码为CON);句柄2:标准错误stderr,输出到命令提示符窗口(console,代码为CON)
其中的stdin可被<重定向,stdout可被>、>>重定向,而stderr在DOS下不可直接重定向,只有通过ctty或其它命令将系统控制权转交给其它设备的方式,来间接完成。
6、| 命令管道符 格式:第一条命令 | 第二条命令 [| 第三条命令...]
将第一条命令的结果作为第二条命令的参数来使用,
例如:dir c:/|find "txt" ::查找C:/所有,并发现TXT字符串。
不使用format的参数时,我是这样来自动格式化A盘的echo y|format a: /s /q /v:system
7、^ 转义字符
^是对特殊符号<,>,&的前导字符,在命令中他将以上3个符号的特殊功能去掉,仅仅只把他们当成符号而不使用他们的特殊意义。
echo test ^>1.txt 结果则是:test > 1.txt
例:
@echo off
echo 英雄^
是^
好^
男人
pause
8、& 组合命令
比如:dir z:/ & dir y:/ & dir c:/::以上命令会连续显示z,y,c盘的内容,不理会该盘是否存在
9、&& 组合命令 dir z:/ && dir y:/ && dir c:/
10、|| 组合命令 把C盘和D盘的文件和文件夹列出到a.txt文件中。
例:dir c:/ && dir d:/ > a.txt这样执行后a.txt里只有D盘的信息!
必须得这么写: dir c:/ > a.txt && dir d:/ >> a.txt
11、""字符串界定符 双引号允许在字符串中包含空格,进入一个特殊目录可以用如下方法
cd "program files";cd progra~1;cd pro* 以上三种方法都可以进入program files这个目录
12、, 逗号 逗号相当于空格 比如:dir,c:/
13、; 分号 当命令相同时,可以将不同目标用来隔离,如果目标路径不存在,则终止执行;如果路径存在,文件不存在,则继续执行。
比如:dir c:/;d:/;e:/;z:/以上命令相当于
dir c:/
dir d:/
dir e:/
dir z:/
例:dir c:/;d:/;e:/1.txt 命令相当于
dir c:/
dir d:/
dir e:/1.txt
14、() 括号 这些命令将被看成一个整体,视为一条命令行。
例: 命令:echo 1 & echo 2 & echo 3
可以写成:
(
echo 1
echo 2
echo 3
) 注意:这种多条命令被视为一条命令行时,如果其中有变量,就涉及到变量延迟的问题。
15、! 感叹号
FOR 专题讲座
FOR 参数 %%变量名 IN (相关文件或命令) DO 执行的命令参数:FOR有4个参数 /d /l /r /f 他们的作用我在下面用例子解释%%变量名 :这个变量名他们区分大小写。
FOR %%variable IN (set) DO command [command-parameters]
%%variable 指定一个单一字母可替换的参数。
(set) 指定一个或一组文件。可以使用通配符。
command 指定对每个文件执行的命令。
command-parameters 为特定命令指定参数或命令行开关。
一、参数 /d 只能显示当前目录下的目录名字
FOR /D %%variable IN (set) DO command [command-parameters]
@echo off
for /d %%i in (c:/*) do echo %%i
pause
运行会把C盘根目录下的全部目录名字打印出来,而文件名字一个也不显示!
在来一个,比如我们要把当前路径下文件夹的名字只有1-3个字母的打出来
@echo off
for /d %%i in (???) do echo %%i
pause
这样的话如果你当前目录下有目录名字只有1-3个字母的,就会显示出来,没有就不显示了
@echo off
for /d %%i in (window?) do echo %%i
pause
保存到C盘下执行.显示:windows
二、参数 /R
FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]
检查以 [drive:]path 为根的目录树,指向每个目录中的
FOR 语句。如果在 /R 后没有指定目录,则使用当前目录。如果集仅为一个单点(.)字符,则枚举该目录树。
例1:
@echo off
for /r c:/ %%i in (*.exe) do echo %%i
pause
以当前目录为搜索路径:目录和他下面的子目录的全部EXE文件列出来!!!
例3:
@echo off
for /r c:/ %%i in (boot.ini) do echo %%i
pause
运行本例发现枚举了c盘所有目录,为了只列举boot.ini存在的目录,可改成下面这样:
@echo off
for /r c:/ %%i in (boot.ini) do if exist %%i echo %%i
pause
三、参数 /L
FOR /L %variable IN (start,step,end) DO command [command-parameters]
该集表示以增量形式从开始到结束的一个数字序列。
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
保存执行看效果,他会打印从1 2 3 4 5 这样5个数字
@echo off
for /l %%i in (1,1,5) do start cmd
pause
当然我们也可以把那个start cmd改成md %%i 这样就会建立指定个目录了!!!名字为1-65535
四、参数 /F /迭代及文件解析在没有使用令牌选项时,/F 将只检查第一个令牌。默认情况下,/F 传递每个文件每一行的第一个空白分隔符号。跳过空行"options"包括一个或多个
FOR /F ["options"] %variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %variable IN ('command') DO command [command-parameters]
例1:
@echo off
rem 首先建立临时文件test.txt
echo ;注释行,这是临时文件,用完删除 >test.txt
echo 11段 12段 13段 14段 15段 16段 >>test.txt
echo 21段,22段,23段,24段,25段,26段 >>test.txt
echo 31段-32段-33段-34段-35段-36段 >>test.txt
FOR /F "eol=; tokens=1,3* delims=,- " %%i in (test.txt) do echo %%i %%j %%k
Pause
Del test.txt
运行显示结果:
11段 13段 14段 15段 16段
21段 23段 24段,25段,26段
31段 33段 34段-35段-36段
请按任意键继续. . .
eol=; 分号开头的行为注释行
tokens=1,3* 将每行第1段,第3段和剩余字段分别赋予变量%%i,%%j,%%k
delims=,- (减号后有一空格)以逗号减号和空格为分隔符,空格必须放在最后
For命令例2:****************************************
@echo off
FOR /F "eol= delims=" %%i in (test.txt) do echo %%i
Pause
运行将显示test.txt全部内容,包括注释行。
For命令例3:****************************************
另外/F参数还可以以输出命令的结果看这个例子
@echo off
FOR /F "delims=" %%i in ('net user') do @echo %%i
pause
这样你本机全部帐号名字就出来了把扩号内的内容用两个单引号引起来就表示那个当命令执行,FOR会返回命令的每行结果,加那个"delims=" 是为了让空格的行能整行显示出来,不加就是只显示空格左边一列!比如:FOR /F %%z IN ('set') DO @echo %%z
这里我们代入的变量名是z那么我们就要把那个I改成z,例如%~fI改为%~fz
一、~I 删除任何引号("),扩展 %I
首先建立临时文件temp.txt,内容如下
"1111
"2222"
3333"
"4444"44
"55"55"55
可建立个BAT文件代码如下:
@echo off
echo ^"1111>temp.txt
echo "2222">>temp.txt
echo 3333^">>temp.txt
echo "4444"44>>temp.txt
echo ^"55"55"55>>temp.txt
rem 上面建立临时文件,注意不成对的引号要加转义字符^,重定向符号前不要留空格
FOR /F "delims=" %%i IN (temp.txt) DO echo %%~i
pause
del temp.txt
执行后,我们看CMD的回显如下:
1111 #字符串前的引号被删除了
2222 #字符串首尾的引号都被删除了
3333" #字符串前无引号,后面的引号保留
4444"44 #字符串前面的引号删除了,而中间的引号保留
55"55"55 #字符串前面的引号删除了,而中间的引号保留
请按任意键继续. . ..
和之前temp.txt中的内容对比一下,我们会发现第1、2、5行的引号都消失了,这就是删除引号~i的作用了!
无头不删,有头连尾删,无尾则删首。
1、若字符串首尾同时存在引号,则删除首尾的引号;2、若字符串尾不存在引号,则删除字符串首的引号;3、如果字符串中间存在引号,或者只在尾部存在引号,则不删除。
二、 %~fI - 将 %I 扩展到一个完全合格的路径名
看例子:
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~fi
pause
执行后显示内容如下
C:/Documents and Settings/Administrator/桌面/test.bat
C:/Documents and Settings/Administrator/桌面/test.vbs
当我把代码中的 %%~fi直接改成%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%i
pause
执行后就会显示以下内容:
test.bat
test.vbs
也就是如果%i变量的内容是一个文件名的话,他就会把这个文件所在的绝对路径打印出来,而不只单单打印一个文件名
三、%~dI - 仅将 %I 扩展到一个驱动器号
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~di
pause
执行后我CMD里显示如下
C:
C:
如果变量%%i的内容是一个文件或者目录名,会把这文件或者目录所在的盘符号打印出来!
四、 %~pI 仅将 %I 扩展到一个路径‘这个用法和上面一样,他只打印路径不打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~pi
pause
五、 %~nI - 仅将 %I 扩展到一个文件名;只打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ni
pause
六、 %~xI - 仅将 %I 扩展到一个文件扩展名;只打印文件的扩展名
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~xi
pause
七、 %~sI - 扩展的路径只含有短名;打印绝对短文件名
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~si
pause
八、 %~aI - 将 %I 扩展到文件的文件属性;打印文件的属性
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ai
pause
九、 %~tI - 将 %I 扩展到文件的日期/时间;打印文件建立的日期
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ti
pause
十、 %~zI - 将 %I 扩展到文件的大小;打印文件的大小
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~zi
pause
上面例子中的"delims=="可以改为"delims=",即不要分隔符
十一、%~$PATH:I查找列在路径环境变量的目录,并将 %I 扩展到找到的第一个完全合格的名称。如果环境变量名未被定义,或者没有找到文件,此组合键会扩展到空字符串把这些代码保存为批处理,放在桌面。
@echo off
FOR /F "delims=" %%i IN (“notepad.exe”) DO echo %%~$PATH:i
pause
一、系统变量
%ALLUSERSPROFILE% 本地 返回“所有用户”配置文件的位置。
%APPDATA% 本地 返回默认情况下应用程序存储数据的位置。
%CD% 本地 返回当前目录字符串。
%CMDCMDLINE% 本地 返回用来启动当前的 Cmd.exe 的准确命令行。
%CMDEXTVERSION% 系统 返回当前的“命令处理程序扩展”的版本号。
%COMPUTERNAME% 系统 返回计算机的名称。
%COMSPEC% 系统 返回命令行解释器可执行程序的准确路径。
%DATE% 系统 返回当前日期。使用与 date /t 命令相同的格式由 Cmd.exe 生成。
%ERRORLEVEL% 系统 返回上一条命令的错误代码。通常用非零值表示错误。
%HOMEDRIVE% 系统 返回连接到用户主目录的本地工作站驱动器号。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。
%HOMEPATH% 系统 返回用户主目录的完整路径。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。
%HOMESHARE%系统返回用户的共享主目录的网络路径基主目录值而设置用户主目录是
在“本地用户和组”中指定的。
%LOGONSERVER% 本地 返回验证当前登录会话的域控制器的名称。
%NUMBER_OF_PROCESSORS% 系统 指定安装在计算机上的处理器的数目。
%OS% 系统 返回操作系统名称。Windows 2000 显示其操作系统为 Windows_NT。
%PATH% 系统 指定可执行文件的搜索路径。
%PATHEXT% 系统 返回操作系统认为可执行的文件扩展名的列表。
%PROCESSOR_ARCHITECTURE% 系统 返回处理器的芯片体系结构。值:x86 或 IA64 基于Itanium
%PROCESSOR_IDENTFIER% 系统 返回处理器说明。
%PROCESSOR_LEVEL% 系统 返回计算机上安装的处理器的型号。
%PROCESSOR_REVISION% 系统 返回处理器的版本号。
%PROMPT% 本地 返回当前解释程序的命令提示符设置。由 Cmd.exe 生成。
%RANDOM% 系统 返回 0 到 32767 之间的任意十进制数字。由 Cmd.exe 生成。
%SYSTEMDRIVE% 系统 返回包含 Windows server operating system 根目录(即系统根目录)的驱动器。
%SYSTEMROOT% 系统 返回 Windows server operating system 根目录的位置。
%TEMP% 和 %TMP% 系统和用户 返回对当前登录用户可用的应用程序所使用的默认临时目录。有些应用程序需要 TEMP,而其他应用程序则需要 TMP。
%TIME% 系统 返回当前时间。使用与 time /t 命令相同的格式。由 Cmd.exe 生成。有关
time 命令的详细信息,请参阅 Time。
%USERDOMAIN% 本地 返回包含用户帐户的域的名称。
%USERNAME% 本地 返回当前登录的用户的名称。
%USERPROFILE% 本地 返回当前用户的配置文件的位置。
%WINDIR% 系统 返回操作系统目录的位置。
这么多系统变量,我们如何知道他的值是什么呢?
在CMD里输入 echo %WINDIR%
这样就能显示一个变量的值了!
举个实际例子,比如我们要复制文件到当前帐号的启动目录里就可以这样
copy d:/1.bat "%USERPROFILE%/「开始」菜单/程序/启动/"
%USERNAME% 本地 返回当前登录的用户的名称。 注意有空格的目录要用引号引起来
另外还有一些系统变量,他们是代表一个意思,或者一个操作!www.cmdos.net
他们分别是%0 %1 %2 %3 %4 %5 ......一直到%9 还有一个%*
%0 这个有点特殊,有几层意思,先讲%1-%9的意思.
%1 返回批处理的第一个参数
%2 返回批处理的第二个参数
%3-%9依此推类
我们看这个例子,把下面的代码保存为test.BAT然后放到C盘下
@echo off
echo %1 %2 %3 %4
echo %1
echo %2
echo %3
echo %4
进入CMD,输入cd c:/
然后输入test.bat我是第一个参数 我是第二个参数 我是第三个参数 我是第四个参数
注意中间的空格,我们会看到这样的结果:
我是第一个参数 我是第二个参数 我是第三个参数 我是第四个参数
我是第一个参数
我是第二个参数
我是第三个参数
我是第四个参数
对比下代码,%1就是”我是第一个参数” %2就是”我是第二个参数”这些%1和%9可以让批处理也能带参数运行,大大提高批处理功能!
例:
@echo off
echo %*
同样保存为test.bat 放到C盘
进入CMD,输入cd c:/
然后输入 test.bat 我是第一个参数 我是第二个参数 我是第三个参数 我是第四个参数
可以看到他一次把全部参数都显示出来了
%0 这个不是返回参数的值了,他有两层意思!
第一层意思:返回批处理所在绝对路径
@echo off
echo %0
pause
保存为test.BAT放在桌面运行,会显示如下结果"C:/Documents and Settings/Administrator/桌面/test.bat"他把当前批处理执行的所在路经打印出来了,返回批处理所在绝对路径的意思。
第二层意思:无限循环执行BAT
例子:
@echo off
net user
%0
二、自定义变量
1、用set命令设置自定义变量
显示、设置或删除 cmd.exe 环境变量。
SET [variable=[string]] variable 指定环境变量名;string 指定要指派给变量的一系列字符串。
要显示当前环境变量,键入不带参数的 SETSET;命令不允许变量名含有等号。
例子:
@echo off
set var=我是值
echo %var%
pause
请看 set var=我是值 ,这就是BAT直接在批处理中设置变量的方法!
在批处理中我们要引用这个变就把var变量名用两个%(百分号)扩起来,如%var%
现在我就来说说SET的这种语法,只需要加一个"/P"参数就可以了。
SET /P variable=[promptString]
@echo off
set /p var=请输入变量的值:
echo 您输入了 %var% ~_~
pause
set /p 是命令语法 var是变量名 =号右边的"请输入变量的值: "
运行后,我们在提示语后面直接输入1,就会显示一行您输入了 1 ~_~
2、用set命令进行简单计算
语法:SET /A expression /A 命令行开关指定等号右边的字符串为被评估的数字表达式。注意:DOS计算只能精确到整数
例:
@echo off
set /p input=请输入计算表达式:
set /a var=%input%
echo 计算结果:%input%=%var%
pause
请输入计算表达式:1+9+20+30-10
计算结果:1+9+20+30-10=50
上面的计算过程显示,DOS计算只能精确到32位,这个32位是指二进制32位,其中最高位为符号位(0为正,1为负),低位31位为数值。31个1换成十进制为2147483647,所以DOS计算的有效值范围是-2147483647至2147483647,超出该数值范围时计算出错。
运行set /a a=1+1,b=2+1,c=3+1后会显示一个4
有时候我们需要直接在原变量进行加减操作就可以用这种语法
set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1
set /a var*=2
对于"逻辑或取余操作符",我们需要把他们用双引号引起来,也可以用转义字符^
set /a var= 1 "&" 1 这样结果就显示出来了,其他逻辑或取余操作符用法
set /a var= 1 "+" 1 异运算
set /a var= 1 "%" 1 取模运算
set /a var= 3 "<<" 2 左移位运算, 3的二进制为11,左移2位为1100。
set /a var= 4 ">>" 2右移位运算,4的二进制为100,右移动2位为1,结果为1
这些符号也可以用&= ^= |= <<= >>= 这样的简单用法如
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号
思考题:求2的n次方
@echo off
set /p n=请输入2的几次方:
set /a num=1^<^<n rem
pause
3、用set命令进行字符串处理
(1)、字符串替换
现在说%PATH:str1=str2%
上面语法的意思就是:将字符串变量%PATH%中的str1替换为str2且是替换变量值的内容
@echo off
set a= bbs. verybat. cn
echo 替换前的值: "%a%"
set var=%a: =%
echo 替换后的值: "%var%"
pause
替换前的值: " bbs. verybat. cn"
替换后的值: "bbs.verybat.cn"
把上面的例子改成这样
@echo off
set a=bbs.verybat.cn
echo 替换前的值: "%a%"
set var=%a: =伤脑筋%
echo 替换后的值: "%var%"
pause
运行显示:
替换前的值: "bbs.verybat.cn"
替换后的值: "bbs伤脑筋verybat伤脑筋cn"
(2)、字符串截取 语法格式为:%a:~[m[,n]]%
方括号表示可选,%为变量标识符,a为变量名,不可少,冒号用于分隔变量名和说明部分,符号~可以简单理解为“偏移”即可,m为偏移量(缺省为0),n为截取长度(缺省为全部)
能例1:
@echo off
set a=bbs.verybat.cn
set var=%a:~1,2%
echo %var%
pause
其他两种语法
%PATH:~-10%
%PATH:~0,-2%
例2:
@echo off
set a=bbs.verybat.cn
set var=%a:~-3%
echo %var%
pause
运行结果:.cn
例3:
@echo off
set a=bbs.verybat.cn
set var=%a:~3%
echo %var%
pause
运行显示:.verybat.cn
这个就是把变量a的从第
3位开始后面全部的值给变量VAR
%PATH:~0,-2% 例子
例4:
@echo off
set a=bbs.verybat.cn
set var=%a:~0,-3%
echo %var%
pause
执行批处理程序中的条件处理。
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
NOT 指定只有条件为 false 的情况下, Windows XP才应该执行该命令。
ERRORLEVEL number 如果最后运行的程序返回一个等于或大于指定数字的退出编码,指定条件为 true。
string1==string2 如果指定的文字字符串匹配,指定条件为 true。
EXIST filename 如果指定的文件名存在,指定条件为 true。
command如果符合条件,指定要执行的命令。如果指定的条件为 FALSE,命令后可跟一个执行 ELSE 关键字后的命令的 ELSE 命令。
ELSE 子句必须在 IF 之后出现在同一行上。例如:
IF EXIST filename (
del filename
) ELSE (
echo filename missing
)
第一种用法:IF [NOT] ERRORLEVEL number command 判断上一条命令执行结果的代码,以决定下一个步骤。一般上一条命令的执行结果代码只有两结果,"成功"用0表示
举个例子:
@echo off
net user
IF %ERRORLEVEL% == 0 echo net user 执行成功了!
pause
这是个简单判断上条命令是否执行成功.www.cmdos.net
这只是一般的情况,实际上,errorlevel返回值可以在0~255之间。比如,xcopy默认的errorlevel值就有5个,分别表示5种执行状态:
0 文件复制没有错误。
1、if errorlevel 2 echo;2、用户按 CTRL+C 终止了 xcopy;3、出现了初始化错误。没有足够的内存或磁盘空间或命令行上输入了无效的驱动器名称或语法;4、出现了磁盘写入错误。
if errorlevel 5 echo出现了磁盘写入错误
if errorlevel 4 echo出现了初始化错误
if errorlevel 2 echo用户按 CTRL+C 终止了 xcopy
if errorlevel 1 echo if errorlevel 2 echo
if errorlevel 0 echo文件复制没有错误。
例1
@echo off
net usertest
IF %ERRORLEVEL% == 1 echo net user 执行失败了!
pause
例2
@echo off
set /p var=随便输入个命令:
%var%
if %ERRORLEVEL% == 0 goto yes
goto no
:yes
echo !var! 执行成功了
pause
exit
:no
echo 基本上执行失败了..
pause
在来一个简化版的
@echo off
set /p var=随便输入个命令:
%var%
if %ERRORLEVEL% == 0 (echo %var%执行成功了) ELSE echo %var%执行失败了!
pause
当然我门还可以把if else这样的语句分成几行写出来,使他看上去好看点...
@echo off
set /p var=随便输入个命令:
%var%
if %ERRORLEVEL% == 0 (
echo !var! 执行成功了
) ELSE (
echo 基本上执行失败了..
)
pause
第二种用法:IF [NOT] string1==string2 command
例子
@echo off
set /p var=请输入第一个比较字符:
set /p var2=请输入第二个比较字符:
if %var% == %var2% (echo 我们相等) ELSE echo 我们不相等
pause
下面的例子打上了括号是为了区别是否有空格。
@echo off
set /p var=请输入第一个比较字符:
set /p var2=请输入第二个比较字符(多输入个空格试试):
if "%var%" == "%var2%" (echo 我们相等) ELSE echo 我们不相等
pause
第三种用法:IF [NOT] EXIST filename command
例子
@echo off
if exist "c:/test" (echo 存在文件) ELSE echo 不存在文件
pause
第四种用法:IF增强的用法
IF [/i] string1 compare-op string2 command /i的意思是不比较时不区分大小写。
IF CMDEXTVERSION number command
IF DEFINED variable command
CMDEXTVERSION 条件的作用跟 ERRORLEVEL 的一样,除了它是在跟与命令扩展名有关联的内部版本号比较。第一个版本是 1。每次对命令扩展名有相当大的增强时,版本号会增加一个。命令扩展名被停用时CMDEXTVERSION 条件不是真的。如果已定义环境变量,DEFINED 条件的作用跟 EXISTS 的一样,除了它取得一个环境变量,返回的结果是 true。
@echo off
if a == A (echo 我们相等) ELSE echo 我们不相等
pause
执行后会显示:我们不相等
@echo off
if /i a == A (echo 我们相等) ELSE echo 我们不相等
pause
我们相等
EQU -等于;NEQ -不等于;LSS -小于;LEQ -小于或等于;GTR -大于;GEQ -大于或等于
@echo off
set /p var=请输入一个数字:
if %var% LEQ 4 (echo 我小于等于4) ELSE echo 我不小于等于4
pause
三、交互界面设计
@echo off&title DOS资源站 www.cmdos.net
cls
title 终极多功能修复
:menu
cls
color 0A
echo.
echo ==============================
echo 请选择要进行的操作,然后按回车
echo ==============================
echo.
echo 1.网络修复及上网相关设置,修复IE,自定义屏蔽网站
echo.
echo 2.病毒专杀工具,端口关闭工具,关闭自动播放
echo.
echo 3.清除所有多余的自启动项目,修复系统错误
echo.
echo 4.清理系统垃圾,提高启动速度
echo.
echo Q.退出
echo.
echo.
:cho
set choice=
set /p choice= 请选择:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="1" goto ip
if /i "%choice%"=="2" goto setsave
if /i "%choice%"=="3" goto kaiji
if /i "%choice%"=="4" goto clean
if /i "%choice%"=="Q" goto endd
echo 选择无效,请重新输入
echo.
goto cho
二、if…else…条件语句
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
增强用法:IF [/i] string1 compare-op string2 command
例:
IF EXIST filename (
del filename
) ELSE (
echo filename missing
)也可写成:if exist filename (del filename) else (echo filename missing)
但这种写法不适合命令太多或嵌套命令的使用。
三、循环语句
1、指定次数循环
FOR /L %variable IN (start,step,end) DO command [command-parameters]
组合命令:
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
)
2、对某集合执行循环语句。
FOR %%variable IN (set) DO command [command-parameters]
FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]
检查以 [drive:]path 为根的目录树,指向每个目录中的FOR 语句。如果在 /R 后没有指定目录,则使用当前目录。如果集仅为一个单点(.)字符,则枚举该目录树。
同前面一样,command可以用括号来组合:
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)
3、条件循环 利用goto语句和条件判断,dos可以实现条件循环
@echo off
set var=0
rem ************循环开始了
:continue
set /a var+=1
echo 第%var%此循环
if %var% lss 100 goto continue
rem ************循环结束了
echo 循环执行完毕
pause
四、子程序
在批处理程序中可以调用外部可运行程序,比如exe程序,也可调用其他批处理程序,这些也可以看作子程序,但是不够方便,如果被调用的程序很多,就显得不够简明了,很繁琐,在windowsXP中,批处理可以调用本程序中的一个程序段,相当于子程序,这些子程序一般放在主程序后面。
子程序调用格式:
CALL :label arguments
子程序语法:
:label
command1
command2
...
commandn
goto :eof
传至子程序的参数在call语句中指定,在子程序中用%1、%2至%9的形式调用,而子程序返回主程序的数据只需在调用结束后直接引用就可以了,当然也可以指定返回变量。
例1:
@echo off
call :sub return 你好
echo 子程序返回值:%return%
pause
:sub
set %1=%2
goto :eof
运行结果:你好
子程序例2:设计一个求多个整数相加的子程序
@echo off
set sum=0
call :sub sum 10 20 35
echo 数据求和结果:%sum%
pause
:sub
rem 参数1为返回变量名称
set /a %1=%1+%2
shift /2
if not "%2"=="" goto sub
goto :eof
运行结果:65
五、用ftp命令实现自动下载 ftp是常用的下载工具,ftp界面中有40多个常用命令。
六、用7-ZIP实现命令行压缩和解压功能 详细情况见7-zip帮助文件
七、调用VBScript程序 用法:CScript 脚本名称 [脚本选项...] [脚本参数...]
八、将批处理转化为可执行文件:由于批处理文件是一种文本文件,任何人都可以对其进行随便编辑,所以如果将其转换成.com格式的可执行文件,不仅执行效率会大大提高,而且不会破坏原来的功能,更能将优先级提到最高。Bat2Com就可以完成这个转换工作。
小知识:在DOS环境下,可执行文件的优先级由高到低依次为.com>.exe>.bat>.cmd。
九、时间延迟:执行一条命令后延迟一段时间再进行下一条命令。
1、利用ping命令延时
@echo off
echo 延时前!
ping /n 3 127.0.0.1 >nul
echo 延时后!
pause
解说:用到了ping命令的“/n”参数,表示要发送多少次请求到指定的ip。本例中要发送3次请求到本机的ip,(127.0.0.1)。127.0.0.1可简写为127.1。
2、利用for命令延时
@echo off
echo 延时前!
for /l %%i in (1,1,5000) do echo %%i>nul
echo 延时后!
pause
十、模拟进度条
@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo 程序正在初始化. . .
echo.
echo ┌──────────────────────────────────────┐
set/p= ■<nul
for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo 100%%
echo └──────────────────────────────────────┘
pause
解说:“set /p = ■<nul”的意思是:只显示提示信息“■”且不换行,也不需手工输入任何信息,这样可以使每个“■”在同一行逐个输出。“ping /n 1 127.1>nul”是输出每个“■”的时间间隔,即每隔多少时间输出一个“■”。
如若内容造成侵权/违法违规/事实不符,请联系编程学习网邮箱:809451989@qq.com进行投诉反馈,一经查实,立即删除!
相关文章
- youtube-dl下载最高画质 音频 内嵌字幕 MP4 m4a合并 视频列表 教程
文章目录1. 工具下载2. Windows 需配置环境变量3. 验证是否可用3.1 参数说明 youtube-dl --proxy [http(s)/socks5]//user:password@your_proxy.com:port -f bestvideo[ext=mp4]+bestaudio[ext=m4a]/bestvideo+bestaudio --merge-output-format mp4 --write-auto-sub --sub-la…...
2024/4/28 19:18:29 - fedora下安装apache过程实录
前提:fedora18系统一个,安装于虚拟机 网络必须确保畅通下载httpd-2.4.3.tar.gzapr-util-1.5.1.tar.gzapr-1.4.6.tar.gzpcre-8.32.tar.gz这四个安装包在http://download.csdn.net/detail/heikefangxian23/8966093都有,一次下载,终身免忧!!解压 & 编译[root@localhost bin]…...
2024/4/28 4:47:25 - destoon大文件上传设置
V4.0支持swfupload带进度提示上传大文件,对于视频和下载频道,需要上传的文件体积可能较大,所以要做以下设置才可以正常上传。1.修改php.ini post_max_size 参数,例如修改为100M2.修改php.ini upload_max_filesize 参数,例如修改为100M3.修改网站设置,安全中心,允许上传…...
2024/4/28 18:06:50 - dos批处理选择菜单方法
dos批处理选择菜单方法 cls @ECHO OFF CLS color 0a GOTO MENU :MENU ECHO. ECHO. =-=-=-=-=批处理菜单示例=-=-=-=-= ECHO. ECHO. 1 执行命令a ECHO. ECHO. 2 执行命令b ECHO. ECHO. 3 执…...
2024/4/28 11:26:42 - Python下载B站指定视频号的所有视频到本地
最近自己打了个个人博客,文章写在了个人博客上面,欢迎访问!地址:LYQs Blog 。...
2024/4/28 15:21:10 - DOS批处理入门教程
贴一篇很好的DOS批处理入门教程这是一篇技术教程,我会用很简单的文字表达清楚自己的意思,你要你识字就能看懂,就能学到知识。写这篇教程的目的,是让每一个看过这些文字的朋友记住一句话:如果爱可以让事情变的更简单,那么就让它简单吧!看这篇教程的方法,就是慢!慢慢的,…...
2024/4/28 1:05:18 - Newsgroup18828文本分类器、文本聚类器、关联分析频繁模式挖掘算法的Java实现工程下载及运行FAQ
Newsgroup18828文本分类器、文本聚类器、关联分析频繁模式挖掘算法的Java实现系列5篇博文自发表半年多来,累计浏览量近万次,Eclipse工程下载累计近千次,受到了很多朋友的关注,如果能给各位数据挖掘入门学习带来一些帮助本人感到很高兴。有很多朋友阅读代码成功运行工程输出…...
2024/4/28 15:33:45 - DOS批处理高级教程:第七章 DOS批处理编程高级技巧(转)
DOS批处理高级教程:第一章 批处理基础DOS批处理高级教程:第二章 DOS循环for命令详解DOS批处理高级教程:第三章 for命令中的变量DOS批处理高级教程:第四章 批处理中的变量DOS批处理高级教程:第五章 set命令详解DOS批处理高级教程:第六章 if命令讲解DOS批处理高级教程:第七…...
2024/4/28 12:12:50 - 7000个源码批量下载
7000个源码批量下载 < type="text/javascript" language="JavaScript">document.title="7000个源码批量下载 - "+document.title http://asp.lt263.com/soft/SaGuestBook.rar 安全天使字符界面留言本(SaGuestBook) http://asp.lt263.com/s…...
2024/4/28 14:49:36 - 一寸、两寸证件照photoshop批处理动作
同事经常找我帮助打印一寸、两寸证件照,之前一直是手工裁切和拼版,今天找了一个自动批处理,算是提高一下工作效率。点击下载:数码照片后期处理PS动作合集 非常感谢作者阿明! 使用方法: 下载PAA数码照片后期处理动作合集后: 1) 双击运行paa_20031201.exe(其实就是RAR自…...
2024/4/21 9:59:51 - NCMS网络频道云管理系统(ChannelCheckerV2.0)
智能电视OTT应用的蓬勃发展,ChannelChecker单机版发布后,或者各大智能电视论坛和网络的推荐。据程序后台统计,下载次数超过万次,累计检测网络电视频道源超过百万次。我由此想到如此大量丰富的数据源,完全可以开发成云平台大数据类的应用,实现离线分散的用户的数据汇聚产生…...
2024/4/28 4:32:03 - Postgresql psql文件执行与批处理
示例: 新建一个批处理文件batch.sql,它包含若干子文件,子文件与批处理文件不在同一目录下,批处理文件在C:\batchexc,子文件在C:\objects内,batch.sql的内容:\encoding UTF8;\cd C:/batchexc\set ON_ERROR_STOP 1\set ECHO all\timing on\i ../objects/platform.sql;\…...
2024/4/28 7:10:54 - 今日MySQL故障排除
今天早上,下载频道的数据库压力突然变大,线程数在700上下波动,大量线程处于Locked状态。这些线程主要是对userday_money和source_uesrdown的查询,这两个表目前的数据都超过2百万,难道是数据量太大了。 看看MySQL日志在说吧,还好,日志告诉了我查询慢的原因: 071221 11:12…...
2024/4/21 9:59:49 - Windows批处理(一)
批处理是一系列可执行的命令集合揉成的一个文件,有点类似于日常开发中的一个类。window平台下批处理文件扩展名一般为bat或者cmd先介绍几个简单的命令①: REM 和::这是注释命令,和开发中的//效果是一样的,都是单行注释。有效标号:冒号后面跟一个变量字符串,一般用于goto语…...
2024/4/21 9:59:47 - Spring Batch 批处理框架介绍学习一
前言原文链接:在http://www.importnew.com/26177.html大型的企业应用中,或多或少都会存在大量的任务需要处理,如邮件批量通知所有将要过期的会员等等。而在批量处理任务的过程中,又需要注意很多细节,如任务异常、性能瓶颈等等。那么,使用一款优秀的框架总比我们自己重复地…...
2024/4/21 9:59:46 - IRC下载TLF0day资源
TLF论坛每天会发布0day的资源,以前从来没有尝试着自己下下0day的资源,今天决定要来学习一下如何下载。TLF提供会员FTP下载方式,可是由于FTP数量众多,而且FTP信息需要登陆TLF论坛才能查找,而论坛常常因为负荷过重而没有响应。因此另外一种下载方式更加方便-IRC下载。通过t…...
2024/4/21 9:59:45 - 流星网络电视砖石破解版|流星网络电视2.89破解版下载 v2.89(免安装)
流星网络电视是一款可以观看可收看1000多套全球卫视电视+6000多集热播电视剧和电影的功能强大网络电视软件,同时也是最好的网络电视软件,软件具有节目缓冲快,播放流畅,操作方便,没有任何广告的特点。 点击下载出处:流星网络电视砖石破解版 采用尖端的P2P技术,具有人越多…...
2024/4/24 20:30:17 - 批处理教程1
表面上,后缀是bat的文件就是批处理文件,是一种文本文件,可以用任一款文本编辑器编辑。简单的说,它的作用就是自动的连续执行多条命令,批处理文件的内容就是一条一条的命令。内容可以是DOS命令。bat专用的命令,很简单。 echo、set、@、call、pause、rem 是批处理文件最…...
2024/4/21 9:59:43 - Android_文档学习_UI_Creating Dialogs
Creating Dialogs Android中的Dialog,(既对话框). 包括1)AlertDialog 2)ProgressDialog 3)DatePickerDialog 4)TimePickerDialog 5)Custom Dialog本文测试代码csdn下载频道:http://download.csdn.net/source/2903639我发现要将文档理顺,其实最好就是全文翻译,但我不想这么做…...
2024/4/20 12:30:25 - Dos批处理讲解-1
最近对于批处理技术的探讨比较热,也有不少好的批处理程序发布,但是如果没有一定的相关知识恐怕不容易看 懂和理解这些批处理文件,也就更谈不上自己动手编写了,古语云:“授人以鱼,不如授人以渔。”因为网上好像 并没有一个比较完整的教材,所以抽一点时间写了这片<<简…...
2024/4/21 9:59:41
最新文章
- C++之函数指针与动态内存分配
const int * p &i; //常指针 int * const p &i; //指针常量() 所有的单目运算符自右向左运算 *p; NULL nullptr (c11)空指针,修改了NULL与int之间的关系 返回值为指针的函数不能返回局部变量的地址 局部变量的生存期结束,地…...
2024/4/28 20:36:00 - 梯度消失和梯度爆炸的一些处理方法
在这里是记录一下梯度消失或梯度爆炸的一些处理技巧。全当学习总结了如有错误还请留言,在此感激不尽。 权重和梯度的更新公式如下: w w − η ⋅ ∇ w w w - \eta \cdot \nabla w ww−η⋅∇w 个人通俗的理解梯度消失就是网络模型在反向求导的时候出…...
2024/3/20 10:50:27 - JRT高效率开发
得益于前期的基础投入,借助代码生成的加持,本来计划用一周实现质控物维护界面,实际用来四小时左右完成质控物维护主体,效率大大超过预期。 JRT从设计之初就是为了证明Spring打包模式不适合软件服务模式,觉得Spring打包…...
2024/4/28 3:06:38 - 【VTKExamples::Meshes】第七期 TableBasedClipDataSetWithPolyData
很高兴在雪易的CSDN遇见你 VTK技术爱好者 QQ:870202403 公众号:VTK忠粉 前言 本文分享VTK样例TableBasedClipDataSetWithPolyData,并解析接口vtkTableBasedClipDataSet,希望对各位小伙伴有所帮助! 感谢各位小伙伴的点赞+关注,小易会继续努力分享,一起进步! 你…...
2024/4/26 6:46:58 - 【外汇早评】美通胀数据走低,美元调整
原标题:【外汇早评】美通胀数据走低,美元调整昨日美国方面公布了新一期的核心PCE物价指数数据,同比增长1.6%,低于前值和预期值的1.7%,距离美联储的通胀目标2%继续走低,通胀压力较低,且此前美国一季度GDP初值中的消费部分下滑明显,因此市场对美联储后续更可能降息的政策…...
2024/4/28 13:52:11 - 【原油贵金属周评】原油多头拥挤,价格调整
原标题:【原油贵金属周评】原油多头拥挤,价格调整本周国际劳动节,我们喜迎四天假期,但是整个金融市场确实流动性充沛,大事频发,各个商品波动剧烈。美国方面,在本周四凌晨公布5月份的利率决议和新闻发布会,维持联邦基金利率在2.25%-2.50%不变,符合市场预期。同时美联储…...
2024/4/28 3:28:32 - 【外汇周评】靓丽非农不及疲软通胀影响
原标题:【外汇周评】靓丽非农不及疲软通胀影响在刚结束的周五,美国方面公布了新一期的非农就业数据,大幅好于前值和预期,新增就业重新回到20万以上。具体数据: 美国4月非农就业人口变动 26.3万人,预期 19万人,前值 19.6万人。 美国4月失业率 3.6%,预期 3.8%,前值 3…...
2024/4/26 23:05:52 - 【原油贵金属早评】库存继续增加,油价收跌
原标题:【原油贵金属早评】库存继续增加,油价收跌周三清晨公布美国当周API原油库存数据,上周原油库存增加281万桶至4.692亿桶,增幅超过预期的74.4万桶。且有消息人士称,沙特阿美据悉将于6月向亚洲炼油厂额外出售更多原油,印度炼油商预计将每日获得至多20万桶的额外原油供…...
2024/4/28 13:51:37 - 【外汇早评】日本央行会议纪要不改日元强势
原标题:【外汇早评】日本央行会议纪要不改日元强势近两日日元大幅走强与近期市场风险情绪上升,避险资金回流日元有关,也与前一段时间的美日贸易谈判给日本缓冲期,日本方面对汇率问题也避免继续贬值有关。虽然今日早间日本央行公布的利率会议纪要仍然是支持宽松政策,但这符…...
2024/4/27 17:58:04 - 【原油贵金属早评】欧佩克稳定市场,填补伊朗问题的影响
原标题:【原油贵金属早评】欧佩克稳定市场,填补伊朗问题的影响近日伊朗局势升温,导致市场担忧影响原油供给,油价试图反弹。此时OPEC表态稳定市场。据消息人士透露,沙特6月石油出口料将低于700万桶/日,沙特已经收到石油消费国提出的6月份扩大出口的“适度要求”,沙特将满…...
2024/4/27 14:22:49 - 【外汇早评】美欲与伊朗重谈协议
原标题:【外汇早评】美欲与伊朗重谈协议美国对伊朗的制裁遭到伊朗的抗议,昨日伊朗方面提出将部分退出伊核协议。而此行为又遭到欧洲方面对伊朗的谴责和警告,伊朗外长昨日回应称,欧洲国家履行它们的义务,伊核协议就能保证存续。据传闻伊朗的导弹已经对准了以色列和美国的航…...
2024/4/28 1:28:33 - 【原油贵金属早评】波动率飙升,市场情绪动荡
原标题:【原油贵金属早评】波动率飙升,市场情绪动荡因中美贸易谈判不安情绪影响,金融市场各资产品种出现明显的波动。随着美国与中方开启第十一轮谈判之际,美国按照既定计划向中国2000亿商品征收25%的关税,市场情绪有所平复,已经开始接受这一事实。虽然波动率-恐慌指数VI…...
2024/4/28 15:57:13 - 【原油贵金属周评】伊朗局势升温,黄金多头跃跃欲试
原标题:【原油贵金属周评】伊朗局势升温,黄金多头跃跃欲试美国和伊朗的局势继续升温,市场风险情绪上升,避险黄金有向上突破阻力的迹象。原油方面稍显平稳,近期美国和OPEC加大供给及市场需求回落的影响,伊朗局势并未推升油价走强。近期中美贸易谈判摩擦再度升级,美国对中…...
2024/4/27 17:59:30 - 【原油贵金属早评】市场情绪继续恶化,黄金上破
原标题:【原油贵金属早评】市场情绪继续恶化,黄金上破周初中国针对于美国加征关税的进行的反制措施引发市场情绪的大幅波动,人民币汇率出现大幅的贬值动能,金融市场受到非常明显的冲击。尤其是波动率起来之后,对于股市的表现尤其不安。隔夜美国股市出现明显的下行走势,这…...
2024/4/25 18:39:16 - 【外汇早评】美伊僵持,风险情绪继续升温
原标题:【外汇早评】美伊僵持,风险情绪继续升温昨日沙特两艘油轮再次发生爆炸事件,导致波斯湾局势进一步恶化,市场担忧美伊可能会出现摩擦生火,避险品种获得支撑,黄金和日元大幅走强。美指受中美贸易问题影响而在低位震荡。继5月12日,四艘商船在阿联酋领海附近的阿曼湾、…...
2024/4/28 1:34:08 - 【原油贵金属早评】贸易冲突导致需求低迷,油价弱势
原标题:【原油贵金属早评】贸易冲突导致需求低迷,油价弱势近日虽然伊朗局势升温,中东地区几起油船被袭击事件影响,但油价并未走高,而是出于调整结构中。由于市场预期局势失控的可能性较低,而中美贸易问题导致的全球经济衰退风险更大,需求会持续低迷,因此油价调整压力较…...
2024/4/26 19:03:37 - 氧生福地 玩美北湖(上)——为时光守候两千年
原标题:氧生福地 玩美北湖(上)——为时光守候两千年一次说走就走的旅行,只有一张高铁票的距离~ 所以,湖南郴州,我来了~ 从广州南站出发,一个半小时就到达郴州西站了。在动车上,同时改票的南风兄和我居然被分到了一个车厢,所以一路非常愉快地聊了过来。 挺好,最起…...
2024/4/28 1:22:35 - 氧生福地 玩美北湖(中)——永春梯田里的美与鲜
原标题:氧生福地 玩美北湖(中)——永春梯田里的美与鲜一觉醒来,因为大家太爱“美”照,在柳毅山庄去寻找龙女而错过了早餐时间。近十点,向导坏坏还是带着饥肠辘辘的我们去吃郴州最富有盛名的“鱼头粉”。说这是“十二分推荐”,到郴州必吃的美食之一。 哇塞!那个味美香甜…...
2024/4/25 18:39:14 - 氧生福地 玩美北湖(下)——奔跑吧骚年!
原标题:氧生福地 玩美北湖(下)——奔跑吧骚年!让我们红尘做伴 活得潇潇洒洒 策马奔腾共享人世繁华 对酒当歌唱出心中喜悦 轰轰烈烈把握青春年华 让我们红尘做伴 活得潇潇洒洒 策马奔腾共享人世繁华 对酒当歌唱出心中喜悦 轰轰烈烈把握青春年华 啊……啊……啊 两…...
2024/4/26 23:04:58 - 扒开伪装医用面膜,翻六倍价格宰客,小姐姐注意了!
原标题:扒开伪装医用面膜,翻六倍价格宰客,小姐姐注意了!扒开伪装医用面膜,翻六倍价格宰客!当行业里的某一品项火爆了,就会有很多商家蹭热度,装逼忽悠,最近火爆朋友圈的医用面膜,被沾上了污点,到底怎么回事呢? “比普通面膜安全、效果好!痘痘、痘印、敏感肌都能用…...
2024/4/27 23:24:42 - 「发现」铁皮石斛仙草之神奇功效用于医用面膜
原标题:「发现」铁皮石斛仙草之神奇功效用于医用面膜丽彦妆铁皮石斛医用面膜|石斛多糖无菌修护补水贴19大优势: 1、铁皮石斛:自唐宋以来,一直被列为皇室贡品,铁皮石斛生于海拔1600米的悬崖峭壁之上,繁殖力差,产量极低,所以古代仅供皇室、贵族享用 2、铁皮石斛自古民间…...
2024/4/28 5:48:52 - 丽彦妆\医用面膜\冷敷贴轻奢医学护肤引导者
原标题:丽彦妆\医用面膜\冷敷贴轻奢医学护肤引导者【公司简介】 广州华彬企业隶属香港华彬集团有限公司,专注美业21年,其旗下品牌: 「圣茵美」私密荷尔蒙抗衰,产后修复 「圣仪轩」私密荷尔蒙抗衰,产后修复 「花茵莳」私密荷尔蒙抗衰,产后修复 「丽彦妆」专注医学护…...
2024/4/26 19:46:12 - 广州械字号面膜生产厂家OEM/ODM4项须知!
原标题:广州械字号面膜生产厂家OEM/ODM4项须知!广州械字号面膜生产厂家OEM/ODM流程及注意事项解读: 械字号医用面膜,其实在我国并没有严格的定义,通常我们说的医美面膜指的应该是一种「医用敷料」,也就是说,医用面膜其实算作「医疗器械」的一种,又称「医用冷敷贴」。 …...
2024/4/27 11:43:08 - 械字号医用眼膜缓解用眼过度到底有无作用?
原标题:械字号医用眼膜缓解用眼过度到底有无作用?医用眼膜/械字号眼膜/医用冷敷眼贴 凝胶层为亲水高分子材料,含70%以上的水分。体表皮肤温度传导到本产品的凝胶层,热量被凝胶内水分子吸收,通过水分的蒸发带走大量的热量,可迅速地降低体表皮肤局部温度,减轻局部皮肤的灼…...
2024/4/27 8:32:30 - 配置失败还原请勿关闭计算机,电脑开机屏幕上面显示,配置失败还原更改 请勿关闭计算机 开不了机 这个问题怎么办...
解析如下:1、长按电脑电源键直至关机,然后再按一次电源健重启电脑,按F8健进入安全模式2、安全模式下进入Windows系统桌面后,按住“winR”打开运行窗口,输入“services.msc”打开服务设置3、在服务界面,选中…...
2022/11/19 21:17:18 - 错误使用 reshape要执行 RESHAPE,请勿更改元素数目。
%读入6幅图像(每一幅图像的大小是564*564) f1 imread(WashingtonDC_Band1_564.tif); subplot(3,2,1),imshow(f1); f2 imread(WashingtonDC_Band2_564.tif); subplot(3,2,2),imshow(f2); f3 imread(WashingtonDC_Band3_564.tif); subplot(3,2,3),imsho…...
2022/11/19 21:17:16 - 配置 已完成 请勿关闭计算机,win7系统关机提示“配置Windows Update已完成30%请勿关闭计算机...
win7系统关机提示“配置Windows Update已完成30%请勿关闭计算机”问题的解决方法在win7系统关机时如果有升级系统的或者其他需要会直接进入一个 等待界面,在等待界面中我们需要等待操作结束才能关机,虽然这比较麻烦,但是对系统进行配置和升级…...
2022/11/19 21:17:15 - 台式电脑显示配置100%请勿关闭计算机,“准备配置windows 请勿关闭计算机”的解决方法...
有不少用户在重装Win7系统或更新系统后会遇到“准备配置windows,请勿关闭计算机”的提示,要过很久才能进入系统,有的用户甚至几个小时也无法进入,下面就教大家这个问题的解决方法。第一种方法:我们首先在左下角的“开始…...
2022/11/19 21:17:14 - win7 正在配置 请勿关闭计算机,怎么办Win7开机显示正在配置Windows Update请勿关机...
置信有很多用户都跟小编一样遇到过这样的问题,电脑时发现开机屏幕显现“正在配置Windows Update,请勿关机”(如下图所示),而且还需求等大约5分钟才干进入系统。这是怎样回事呢?一切都是正常操作的,为什么开时机呈现“正…...
2022/11/19 21:17:13 - 准备配置windows 请勿关闭计算机 蓝屏,Win7开机总是出现提示“配置Windows请勿关机”...
Win7系统开机启动时总是出现“配置Windows请勿关机”的提示,没过几秒后电脑自动重启,每次开机都这样无法进入系统,此时碰到这种现象的用户就可以使用以下5种方法解决问题。方法一:开机按下F8,在出现的Windows高级启动选…...
2022/11/19 21:17:12 - 准备windows请勿关闭计算机要多久,windows10系统提示正在准备windows请勿关闭计算机怎么办...
有不少windows10系统用户反映说碰到这样一个情况,就是电脑提示正在准备windows请勿关闭计算机,碰到这样的问题该怎么解决呢,现在小编就给大家分享一下windows10系统提示正在准备windows请勿关闭计算机的具体第一种方法:1、2、依次…...
2022/11/19 21:17:11 - 配置 已完成 请勿关闭计算机,win7系统关机提示“配置Windows Update已完成30%请勿关闭计算机”的解决方法...
今天和大家分享一下win7系统重装了Win7旗舰版系统后,每次关机的时候桌面上都会显示一个“配置Windows Update的界面,提示请勿关闭计算机”,每次停留好几分钟才能正常关机,导致什么情况引起的呢?出现配置Windows Update…...
2022/11/19 21:17:10 - 电脑桌面一直是清理请关闭计算机,windows7一直卡在清理 请勿关闭计算机-win7清理请勿关机,win7配置更新35%不动...
只能是等着,别无他法。说是卡着如果你看硬盘灯应该在读写。如果从 Win 10 无法正常回滚,只能是考虑备份数据后重装系统了。解决来方案一:管理员运行cmd:net stop WuAuServcd %windir%ren SoftwareDistribution SDoldnet start WuA…...
2022/11/19 21:17:09 - 计算机配置更新不起,电脑提示“配置Windows Update请勿关闭计算机”怎么办?
原标题:电脑提示“配置Windows Update请勿关闭计算机”怎么办?win7系统中在开机与关闭的时候总是显示“配置windows update请勿关闭计算机”相信有不少朋友都曾遇到过一次两次还能忍但经常遇到就叫人感到心烦了遇到这种问题怎么办呢?一般的方…...
2022/11/19 21:17:08 - 计算机正在配置无法关机,关机提示 windows7 正在配置windows 请勿关闭计算机 ,然后等了一晚上也没有关掉。现在电脑无法正常关机...
关机提示 windows7 正在配置windows 请勿关闭计算机 ,然后等了一晚上也没有关掉。现在电脑无法正常关机以下文字资料是由(历史新知网www.lishixinzhi.com)小编为大家搜集整理后发布的内容,让我们赶快一起来看一下吧!关机提示 windows7 正在配…...
2022/11/19 21:17:05 - 钉钉提示请勿通过开发者调试模式_钉钉请勿通过开发者调试模式是真的吗好不好用...
钉钉请勿通过开发者调试模式是真的吗好不好用 更新时间:2020-04-20 22:24:19 浏览次数:729次 区域: 南阳 > 卧龙 列举网提醒您:为保障您的权益,请不要提前支付任何费用! 虚拟位置外设器!!轨迹模拟&虚拟位置外设神器 专业用于:钉钉,外勤365,红圈通,企业微信和…...
2022/11/19 21:17:05 - 配置失败还原请勿关闭计算机怎么办,win7系统出现“配置windows update失败 还原更改 请勿关闭计算机”,长时间没反应,无法进入系统的解决方案...
前几天班里有位学生电脑(windows 7系统)出问题了,具体表现是开机时一直停留在“配置windows update失败 还原更改 请勿关闭计算机”这个界面,长时间没反应,无法进入系统。这个问题原来帮其他同学也解决过,网上搜了不少资料&#x…...
2022/11/19 21:17:04 - 一个电脑无法关闭计算机你应该怎么办,电脑显示“清理请勿关闭计算机”怎么办?...
本文为你提供了3个有效解决电脑显示“清理请勿关闭计算机”问题的方法,并在最后教给你1种保护系统安全的好方法,一起来看看!电脑出现“清理请勿关闭计算机”在Windows 7(SP1)和Windows Server 2008 R2 SP1中,添加了1个新功能在“磁…...
2022/11/19 21:17:03 - 请勿关闭计算机还原更改要多久,电脑显示:配置windows更新失败,正在还原更改,请勿关闭计算机怎么办...
许多用户在长期不使用电脑的时候,开启电脑发现电脑显示:配置windows更新失败,正在还原更改,请勿关闭计算机。。.这要怎么办呢?下面小编就带着大家一起看看吧!如果能够正常进入系统,建议您暂时移…...
2022/11/19 21:17:02 - 还原更改请勿关闭计算机 要多久,配置windows update失败 还原更改 请勿关闭计算机,电脑开机后一直显示以...
配置windows update失败 还原更改 请勿关闭计算机,电脑开机后一直显示以以下文字资料是由(历史新知网www.lishixinzhi.com)小编为大家搜集整理后发布的内容,让我们赶快一起来看一下吧!配置windows update失败 还原更改 请勿关闭计算机&#x…...
2022/11/19 21:17:01 - 电脑配置中请勿关闭计算机怎么办,准备配置windows请勿关闭计算机一直显示怎么办【图解】...
不知道大家有没有遇到过这样的一个问题,就是我们的win7系统在关机的时候,总是喜欢显示“准备配置windows,请勿关机”这样的一个页面,没有什么大碍,但是如果一直等着的话就要两个小时甚至更久都关不了机,非常…...
2022/11/19 21:17:00 - 正在准备配置请勿关闭计算机,正在准备配置windows请勿关闭计算机时间长了解决教程...
当电脑出现正在准备配置windows请勿关闭计算机时,一般是您正对windows进行升级,但是这个要是长时间没有反应,我们不能再傻等下去了。可能是电脑出了别的问题了,来看看教程的说法。正在准备配置windows请勿关闭计算机时间长了方法一…...
2022/11/19 21:16:59 - 配置失败还原请勿关闭计算机,配置Windows Update失败,还原更改请勿关闭计算机...
我们使用电脑的过程中有时会遇到这种情况,当我们打开电脑之后,发现一直停留在一个界面:“配置Windows Update失败,还原更改请勿关闭计算机”,等了许久还是无法进入系统。如果我们遇到此类问题应该如何解决呢࿰…...
2022/11/19 21:16:58 - 如何在iPhone上关闭“请勿打扰”
Apple’s “Do Not Disturb While Driving” is a potentially lifesaving iPhone feature, but it doesn’t always turn on automatically at the appropriate time. For example, you might be a passenger in a moving car, but your iPhone may think you’re the one dri…...
2022/11/19 21:16:57