DOS批处理高级教程：第七章 DOS批处理编程高级技巧(转)

DOS批处理高级教程：第一章批处理基础
DOS批处理高级教程：第二章 DOS循环for命令详解
DOS批处理高级教程：第三章 for命令中的变量
DOS批处理高级教程：第四章批处理中的变量
DOS批处理高级教程：第五章 set命令详解
DOS批处理高级教程：第六章 if命令讲解
DOS批处理高级教程：第七章 DOS批处理编程高级技巧

一、交互界面设计

没啥说的，看看高手设计的菜单界面吧：

@echo off
cls
title 终极多功能修复
:menu
cls
color 0A
echo.
echo ==============================
echo 请选择要进行的操作，然后按回车
echo ==============================
echo.
echo 1.网络修复及上网相关设置,修复IE,自定义屏蔽网站
echo.
echo 2.病毒专杀工具，端口关闭工具,关闭自动播放
echo.
echo 3.清除所有多余的自启动项目，修复系统错误
echo.
echo 4.清理系统垃圾,提高启动速度
echo.
echo Q.退出
echo.
echo.
:cho
set choice=
set /p choice= 请选择:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="1" goto ip
if /i "%choice%"=="2" goto setsave
if /i "%choice%"=="3" goto kaiji
if /i "%choice%"=="4" goto clean
if /i "%choice%"=="Q" goto endd
echo 选择无效，请重新输入
echo.
goto cho

复制代码

只要学完本教程前面的章节，上面的程序应该能看懂了。

二、if…else…条件语句

前面已经谈到，DOS条件语句主要有以下形式
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
增强用法：IF [/I] string1 compare-op string2 command
增强用法中加上/I就不区分大小写了!
增强用法中还有一些用来判断数字的符号：

EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于

上面的command命令都可以用小括号来使用多条命令的组合，包括else子句，组合命令中可以嵌套使用条件或循环命令。

例如:

IF EXIST filename (
      del filename
) ELSE (
      echo filename missing
)

也可写成：
if exist filename (del filename) else (echo filename missing)

但这种写法不适合命令太多或嵌套命令的使用。

三、循环语句

1、指定次数循环

FOR /L %variable IN (start,step,end) DO command [command-parameters]

组合命令：
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
)

2、对某集合执行循环语句。

FOR %%variable IN (set) DO command [command-parameters]

  %%variable  指定一个单一字母可替换的参数。
  (set)    指定一个或一组文件。可以使用通配符。
  command 对每个文件执行的命令，可用小括号使用多条命令组合。

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

检查以 [drive:]path 为根的目录树，指向每个目录中的
FOR 语句。如果在 /R 后没有指定目录，则使用当前
目录。如果集仅为一个单点(.)字符，则枚举该目录树。

同前面一样，command可以用括号来组合：
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)

3、条件循环

上面的循环结构是用for命令来实现的，for命令循环有一个缺点，就是整个循环被当作一条命令语句，涉及到变量延迟的问题。
利用goto语句和条件判断，dos可以实现条件循环，很简单啦，看例子：

例：

@echo off
set var=0
rem ************循环开始了
:continue
set /a var+=1
echo 第%var%次循环
if %var% lss 100 goto continue
rem ************循环结束了
echo 循环执行完毕
pause

复制代码

例：

@echo off
set var=100
rem ************循环开始了
:continue
echo 第%var%次循环
set /a var-=1
if %var% gtr 0 goto continue
rem ************循环结束了
echo 循环执行完毕
pause

复制代码

四、子程序

在批处理程序中可以调用外部可运行程序，比如exe程序，也可调用其他批处理程序，这些也可以看作子程序，但是不够方便，如果被调用的程序很多，就显得不够简明了，很繁琐。

在windowsXP中，批处理可以调用本程序中的一个程序段，相当于子程序，这些子程序一般放在主程序后面。

子程序调用格式：

CALL :label arguments

子程序语法：
:label
command1
command2
......
commandn
goto :eof

在子程序段中，参数%0指标签:label

子过程一般放在最后，并且注意在主程序最后要加上exit或跳转语句，避免错误的进入子过程。

子程序和主程序中的变量都是全局变量，其作用范围都是整个批处理程序。

传至子程序的参数在call语句中指定，在子程序中用%1、%2至%9的形式调用，而子程序返回主程序的数据只需在调用结束后直接引用就可以了，当然也可以指定返回变量，请看下面的例子。

子程序例1：

@echo off
call :sub return 你好
echo 子程序返回值：%return%
pause
:sub
set %1=%2
goto :eof

复制代码

运行结果：你好

子程序例2：设计一个求多个整数相加的子程序

@echo off
set sum=0
call :sub sum 10 20 35
echo 数据求和结果：%sum%
pause
:sub
rem 参数1为返回变量名称
set /a %1=%1+%2
shift /2
if not "%2"=="" goto sub
goto :eof

复制代码

运行结果：65

在win98系统中，不支持上面这种标号调用，须将子程序单独保存为一个批处理程序，然后调用。

五、用ftp命令实现自动下载

ftp是常用的下载工具，ftp界面中有40多个常用命令，自己学习了，不介绍了。这里介绍如何用dos命令行调用ftp命令，实现ftp自动登录，并上传下载，并自动退出ftp程序。

其实可以将ftp命令组合保存为一个文本文件，然后用以下命令调用即可。

ftp  -n -s:[[drive:]path]filename

上面的filename为ftp命令文件，包括登录IP地址，用户名、密码、操作命令等
例：
open 90.52.8.3 ＃打开ip
user iware    ＃用户为iware
password8848 ＃密码
bin          ＃二进制传输模式
prompt
cd tmp1       ＃切换至iware用户下的tmp1目录
pwd
lcd d:\download ＃本地目录
mget *       ＃下载tmp1目录下的所有文件
bye          ＃退出ftp

六、用7-ZIP实现命令行压缩和解压功能

语法格式：（详细情况见7-zip帮助文件，看得头晕可以跳过，用到再学）

7z <command> [<switch>...] <base_archive_name> [<arguments>...]

7z.exe的每个命令都有不同的参数<switch>,请看帮助文件
<base_archive_name>为压缩包名称
<arguments>为文件名称，支持通配符或文件列表

其中，7z是至命令行压缩解压程序7z.exe，<command>是7z.exe包含的命令，列举如下：

a： Adds files to archive. 添加至压缩包
a命令可用参数：
  -i (Include)
  -m (Method)
  -p (Set Password)
  -r (Recurse)
  -sfx (create SFX)
  -si (use StdIn)
  -so (use StdOut)
  -ssw (Compress shared files)
  -t (Type of archive)
  -u (Update)
  -v (Volumes)
  -w (Working Dir)
  -x (Exclude)

b： Benchmark

d： Deletes files from archive. 从压缩包中删除文件
d命令可用参数：
  -i (Include)
  -m (Method)
  -p (Set Password)
  -r (Recurse)
  -u (Update)
  -w (Working Dir)
  -x (Exclude)

e： Extract解压文件至当前目录或指定目录
e命令可用参数：
  -ai (Include archives)
  -an (Disable parsing of archive_name)
  -ao (Overwrite mode)
  -ax (Exclude archives)
  -i (Include)
  -o (Set Output Directory)
  -p (Set Password)
  -r (Recurse)
  -so (use StdOut)
  -x (Exclude)
  -y (Assume Yes on all queries)

l： Lists contents of archive.
t： Test
u： Update

x： eXtract with full paths用文件的完整路径解压至当前目录或指定目录
x命令可用参数：
  -ai (Include archives)
  -an (Disable parsing of archive_name)
  -ao (Overwrite mode)
  -ax (Exclude archives)
  -i (Include)
  -o (Set Output Directory)
  -p (Set Password)
  -r (Recurse)
  -so (use StdOut)
  -x (Exclude)
  -y (Assume Yes on all queries)

七、调用VBScript程序

使用 Windows 脚本宿主，可以在命令提示符下运行脚本。CScript.exe 提供了用于设置脚本属性的命令行开关。

用法：CScript 脚本名称 [脚本选项...] [脚本参数...]

选项：
//B       批模式：不显示脚本错误及提示信息
//D       启用 Active Debugging
//E:engine  使用执行脚本的引擎
//H:CScript 将默认的脚本宿主改为 CScript.exe
//H:WScript 将默认的脚本宿主改为 WScript.exe （默认）
//I       交互模式（默认，与 //B 相对)
//Job:xxxx  执行一个 WSF 工作
//Logo    显示徽标（默认）
//Nologo 不显示徽标：执行时不显示标志
//S       为该用户保存当前命令行选项
//T:nn    超时设定秒：允许脚本运行的最长时间
//X       在调试器中执行脚本
//U       用 Unicode 表示来自控制台的重定向 I/O

“脚本名称”是带有扩展名和必需的路径信息的脚本文件名称，如d:\admin\vbscripts\chart.vbs。
“脚本选项和参数”将传递给脚本。脚本参数前面有一个斜杠 (/)。每个参数都是可选的；但不能在未指定脚本名称的情况下指定脚本选项。如果未指定参数，则 CScript 将显示 CScript 语法和有效的宿主参数。

八、将批处理转化为可执行文件：

由于批处理文件是一种文本文件，任何人都可以对其进行随便编辑，不小心就会把里面的命令破坏掉，所以如果将其转换成.com格式的可执行文件，不仅执行效率会大大提高，而且不会破坏原来的功能，更能将优先级提到最高。Bat2Com就可以完成这个转换工作。

小知识：在DOS环境下，可执行文件的优先级由高到低依次为.com>.exe>.bat>.cmd，即如果在同一目录下存在文件名相同的这四类文件，当只键入文件名时，DOS执行的是name.com，如果需要执行其他三个文件，则必须指定文件的全名，如name.bat。

这是一个只有5.43K大小的免费绿色工具，可以运行在纯DOS或DOS窗口的命令行中，用法：Bat2Com FileName，这样就会在同一目录下生成一个名为FileNme.com的可执行文件，执行的效果和原来的.bat文件一样。

九、时间延迟

什么是时间延迟？顾名思义，就是执行一条命令后延迟一段时间再进行下一条命令。

延迟的应用见下节：“模拟进度条”。

1、利用ping命令延时
例：

@echo off
echo 延时前：%time%
ping /n 3 127.0.0.1 >nul
echo 延时后：%time%
pause

复制代码

解说：用到了ping命令的“/n”参数，表示要发送多少次请求到指定的ip。本例中要发送3次请求到本机的ip（127.0.0.1）。127.0.0.1可简写为127.1。“>nul”就是屏蔽掉ping命令所显示的内容。

2、利用for命令延时
例：

@echo off
echo 延时前：%time%
for /l %%i in (1,1,5000) do echo %%i>nul
echo 延时后：%time%
pause

复制代码

解说：原理很简单，就是利用一个计次循环并屏蔽它所显示的内容来达到延时的目的。

3、利用vbs延迟函数，精确度毫秒，误差1000毫秒内

例：

@echo off
echo %time%
call :delay 5000
echo %time%
pause
exit
:delay
echo WScript.Sleep %1>delay.vbs
CScript //B delay.vbs
del delay.vbs
goto :eof

复制代码

运行显示：
10:44:06.45
10:44:11.95
请按任意键继续. . .

上面的运行结果显示实际延时了5500毫秒，多出来的500毫秒时建立和删除临时文件所耗费的时间。误差在一秒之内。

4、仅用批处理命令实现任意时间延迟，精确度10毫秒，误差50毫秒内

仅用批处理命令就可以实现延迟操作。

例：

@echo off
set /p delay=请输入需延迟的毫秒数：
set TotalTime=0
set NowTime=%time%
::读取起始时间，时间格式为：13:01:05.95
echo 程序开始时间：%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::读取起始时间的分钟数
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::将起始时间的秒数转为毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 读取现在时间的分钟数
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::将现在时间的秒数转为毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序结束时间：%time%
echo 设定延迟时间：%delay%毫秒
echo 实际延迟时间：%TotalTime%毫秒
pause

复制代码

运行显示：

请输入需延迟的毫秒数：6000
程序开始时间：15:32:16.37
程序结束时间：15:32:22.37
设定延迟时间：6000毫秒
实际延迟时间：6000毫秒
请按任意键继续. . .

实现原理：首先设定要延迟的毫秒数，然后用循环累加时间，直到累加时间大于等于延迟时间。

误差：windows系统时间只能精确到10毫秒，所以理论上有可能存在10毫秒误差。
经测试，当延迟时间大于500毫秒时，上面的延迟程序一般不存在误差。当延迟时间小于500毫秒时，可能有几十毫秒误差，为什么？因为延迟程序本身也是有运行时间的，同时系统时间只能精确到10毫秒。

为了方便引用，可将上面的例子改为子程序调用形式：

@echo off
echo 程序开始时间：%Time%
call :delay 10
echo 实际延迟时间：%totaltime%毫秒
echo 程序结束时间：%time%
pause
exit
::-----------以下为延时子程序--------------------
:delay
@echo off
if "%1"=="" goto :eof
set DelayTime=%1
set TotalTime=0
set NowTime=%time%
::读取起始时间，时间格式为：13:01:05.95
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %DelayTime% goto delay_continue
goto :eof

复制代码

十、模拟进度条

下面给出一个模拟进度条的程序。如果将它运用在你自己的程序中，可以使你的程序更漂亮。

@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo 程序正在初始化. . .
echo.
echo ┌──────────────────────────────────────┐
set/p= ■<nul
for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo 100%%
echo └──────────────────────────────────────┘
pause

复制代码

解说：“set /p a=■<nul”的意思是：只显示提示信息“■”且不换行，也不需手工输入任何信息，这样可以使每个“■”在同一行逐个输出。“ping /n 0 127.1>nul”是输出每个“■”的时间间隔，即每隔多少时间输出一个“■”。

十一、特殊字符的输入及应用

开始 -> 运行 -> 输入cmd -> edit -> ctrl+p（意思是允许输入特殊字符）-> 按ctrl+a将会显示笑脸图案。

（如果要继续输入特殊字符请再次按ctrl+p，然后ctrl+某个字母）

以上是特殊字符的输入方法，选自[英雄]教程，很管用的。也就是用编辑程序edit输入特殊字符，然后保存为一文本文件，再在windows下打开此文件，复制其中的特殊符号即可。

一些简单的特殊符号可以在dos命令窗口直接输入，并用重定向保存为文本文件。
例：

C:>ECHO ^G>temp.txt
“^G”是用Ctrl＋G或Alt＋007输入，输入多个^G可以产生多声鸣响。

特殊字符的应用也很有意思，这里仅举一例：退格键

退格键表示删除左边的字符，此键不能在文档中正常输入，但可以通过edit编辑程序录入并复制出来。即“”。

利用退格键，可以设计闪烁文字效果

例：文字闪烁

@echo off
:start
set/p=床前明月光<nul
::显示文字，光标停于行尾
ping -n 0 127.0.0.1>nul
::设置延迟时间
set /p a=<nul
:: 输出一些退格符将光标置于该行的最左端（退格符的数量可以自己调整）。
set /p a= <nul
::输出空格将之前输出的文字覆盖掉。
set /p a=<nul
::再次输出退格符将光标置于该行的最左端，这里的退格符数量一定不能比前面的空格数少。
::否则光标不能退到最左端。
goto start

复制代码

例：输出唐诗一首，每行闪动多次

@echo off
setlocal enabledelayedexpansion

复制代码

set str=床前明月光疑是地上霜举头望明月低头思故乡

::定义字符串str
for %%i in (%str%) do (
rem 由于str中含有空格，则以空格为分隔符将str中的每一个部分依次赋给变量%%i。
set char=%%i
echo.
echo.
for /l %%j in (0,1,5) do (
set/p=!char:~%%j,1!<nul
rem 依次取出变量char中的每一个字符，并显示。
ping -n 0 127.0.0.1>nul
rem 设置输出每个字符的时间延迟。
)
call :hero %%i
)
pause>nul
exit
:hero
for /l %%k in (1,1,10) do (
ping /n 0 127.0.0.1>nul
set /p a=<nul
set /p a= <nul
set /p a=<nul
ping /n 0 127.0.0.1>nul
set /p a=%1<nul
)
::文字闪动
goto :eof

复制代码

十二、随机数（%random%）的应用技巧

%RANDOM% 系统变量返回 0 到 32767 之间的任意十进制数字。由 Cmd.exe 生成。

2的15次方等于32768，上面的0～32767实际就是15位二进制数的范围。

那么，如何获取100以内的随机数呢？很简单，将%RANDOM%按100进行求余运算即可，见例子。

例：生成5个100以内的随机数

@echo off
setlocal enabledelayedexpansion
for /L %%i in (1 1 5) do (
set /a randomNum=!random!%%100
echo 随机数：!randomNum!
)
pause

复制代码

运行结果：（每次运行不一样）
随机数：91
随机数：67
随机数：58
随机数：26
随机数：20
请按任意键继续. . .

求余数运算set /a randomNum=!random!%%100中的100可以是1～32768之间的任意整数。

总结：利用系统变量%random%，求余数运算%%，字符串处理等，可以实现很多随机处理。

思考题目：生成给定位数的随机密码

解答思路：将26个英文字母或10数字以及其它特殊字符组成一个字符串，随机抽取其中的若干字符。

参考答案1：（简单）

@echo off
call :randomPassword 5 pass1 pass2
echo %pass1% %pass2%
pause
exit
:randomPassword
::---------生成随机密码
::---------%1为密码长度，%2及以后为返回变量名称
::---------for命令最多只能区分31个字段
@echo off
set password_len=%1
if not defined password_len goto :eof
if %password_len% lss 1 goto :eof
set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z
set return=
set num=0
:randomPassword1
set /a num+=1
set /a numof=%random%%%26+1
for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i
if %num% lss %password_len% goto randomPassword1
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof

复制代码

参考答案2：（最优）

@echo off
call :randomPassword 6 pass1 pass2 pass3
echo %pass1% %pass2% %pass3%
pause
exit
:randomPassword
::---------生成随机密码
::---------%1为密码长度，%2及以后为返回变量名称
::---------goto循环、变量嵌套、命令嵌套
@echo off
if "%1"=="" goto :eof
if %1 lss 1 goto :eof
set password_len=%1
set return=
set wordset=abcdefghijklmnopqrstuvwxyz023456789_
::---------------------------循环
:randomPassword1
set /a numof=%random%%%36
call set return=%return%%%wordset:~%numof%,1%%
set /a password_len-=1
if %password_len% gtr 0 goto randomPassword1
::---------------------------循环
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof

复制代码

说明：本例涉及到变量嵌套和命令嵌套的应用，见后。

十三、变量嵌套与命令嵌套

和其它编程语言相比，dos功能显得相对简单，要实现比较复杂的功能，需要充分运用各种技巧，变量嵌套与命令嵌套就是此类技巧之一。

先复习一下前面的“字符串截取”的关键内容：

**********************************************
截取功能统一语法格式为：%a:~[m[,n]]%
**********************************************

方括号表示可选，%为变量标识符，a为变量名，不可少，冒号用于分隔变量名和说明部分，符号～可以简单理解为“偏移”即可，m为偏移量（缺省为0），n为截取长度（缺省为全部）。

百分号如果需要当成单一字符，必须写成%%

以上是dos变量处理的通用格式，如果其中的m、n为变量，那么这种情况就是变量嵌套了。

比如设变量word为“abcdefghij”，变量num为“123456789”
%word:~4,1%为e，其中4可以从变量num中取值，即%num:~3,1%，写成组合形式如下：
%word:~%num:~3,1%,1% 经测试这种写法不能正确执行，写成%word:~(%num:~3,1%),1%同样不行，那么，怎么实现这种变量嵌套呢？这就必须结合命令嵌套。

什么是命令嵌套呢？简单的说，首先用一条dos命令生成一个字符串，而这个字符串是另一条dos命令，用call语句调用字符串将其执行，从而得到最终结果。

例：用call语句实现命令嵌套

@echo off
set str1=aaa echo ok bbb
echo 初始字符串：%str1%
echo 生成命令字符串如下：
echo %str1:~4,7%
echo 运行命令字符串生成最终结果为：
call %str1:~4,7%
pause

复制代码

运行显示：
初始字符串：aaa echo ok bbb
生成命令字符串如下：
echo ok
运行命令字符串生成最终结果为：
ok

请按任意键继续. . .

转自：http://club.topsage.com/thread-597604-1-1.html

转载于:https://www.cnblogs.com/zhangpengshou/archive/2011/10/09/2203894.html

查看全文
如若内容造成侵权/违法违规/事实不符，请联系编程学习网邮箱：809451989@qq.com进行投诉反馈，一经查实，立即删除！

7000个源码批量下载
7000个源码批量下载 < type="text/javascript" language="JavaScript">document.title="7000个源码批量下载 - "+document.title http://asp.lt263.com/soft/SaGuestBook.rar 安全天使字符界面留言本(SaGuestBook) http://asp.lt263.com/s…...
2024/4/21 9:59:53
一寸、两寸证件照photoshop批处理动作
同事经常找我帮助打印一寸、两寸证件照，之前一直是手工裁切和拼版，今天找了一个自动批处理，算是提高一下工作效率。点击下载：数码照片后期处理PS动作合集非常感谢作者阿明! 使用方法：下载PAA数码照片后期处理动作合集后： 1）双击运行paa_20031201.exe（其实就是RAR自…...
2024/4/21 9:59:51
NCMS网络频道云管理系统(ChannelCheckerV2.0)
智能电视OTT应用的蓬勃发展，ChannelChecker单机版发布后，或者各大智能电视论坛和网络的推荐。据程序后台统计，下载次数超过万次，累计检测网络电视频道源超过百万次。我由此想到如此大量丰富的数据源，完全可以开发成云平台大数据类的应用，实现离线分散的用户的数据汇聚产生…...
2024/4/28 4:32:03
Postgresql psql文件执行与批处理
示例：新建一个批处理文件batch.sql，它包含若干子文件，子文件与批处理文件不在同一目录下，批处理文件在C:\batchexc，子文件在C:\objects内，batch.sql的内容：\encoding UTF8;\cd C:/batchexc\set ON_ERROR_STOP 1\set ECHO all\timing on\i ../objects/platform.sql;\…...
2024/4/28 7:10:54
今日MySQL故障排除
今天早上，下载频道的数据库压力突然变大，线程数在700上下波动，大量线程处于Locked状态。这些线程主要是对userday_money和source_uesrdown的查询，这两个表目前的数据都超过2百万，难道是数据量太大了。看看MySQL日志在说吧，还好，日志告诉了我查询慢的原因: 071221 11:12…...
2024/4/21 9:59:49
Windows批处理（一）
批处理是一系列可执行的命令集合揉成的一个文件，有点类似于日常开发中的一个类。window平台下批处理文件扩展名一般为bat或者cmd先介绍几个简单的命令①： REM 和::这是注释命令，和开发中的//效果是一样的，都是单行注释。有效标号：冒号后面跟一个变量字符串，一般用于goto语…...
2024/4/21 9:59:47
Spring Batch 批处理框架介绍学习一
前言原文链接：在http://www.importnew.com/26177.html大型的企业应用中，或多或少都会存在大量的任务需要处理，如邮件批量通知所有将要过期的会员等等。而在批量处理任务的过程中，又需要注意很多细节，如任务异常、性能瓶颈等等。那么，使用一款优秀的框架总比我们自己重复地…...
2024/4/21 9:59:46
IRC下载TLF0day资源
TLF论坛每天会发布0day的资源，以前从来没有尝试着自己下下0day的资源，今天决定要来学习一下如何下载。TLF提供会员FTP下载方式，可是由于FTP数量众多，而且FTP信息需要登陆TLF论坛才能查找，而论坛常常因为负荷过重而没有响应。因此另外一种下载方式更加方便－IRC下载。通过t…...
2024/4/21 9:59:45
流星网络电视砖石破解版|流星网络电视2.89破解版下载 v2.89(免安装)
流星网络电视是一款可以观看可收看1000多套全球卫视电视+6000多集热播电视剧和电影的功能强大网络电视软件，同时也是最好的网络电视软件，软件具有节目缓冲快，播放流畅，操作方便，没有任何广告的特点。点击下载出处：流星网络电视砖石破解版采用尖端的P2P技术，具有人越多…...
2024/4/24 20:30:17
批处理教程1
表面上，后缀是bat的文件就是批处理文件，是一种文本文件，可以用任一款文本编辑器编辑。简单的说，它的作用就是自动的连续执行多条命令，批处理文件的内容就是一条一条的命令。内容可以是DOS命令。bat专用的命令，很简单。　　echo、set、@、call、pause、rem　是批处理文件最…...
2024/4/21 9:59:43
Android_文档学习_UI_Creating Dialogs
Creating Dialogs Android中的Dialog,(既对话框). 包括1)AlertDialog 2)ProgressDialog 3)DatePickerDialog 4)TimePickerDialog 5)Custom Dialog本文测试代码csdn下载频道:http://download.csdn.net/source/2903639我发现要将文档理顺,其实最好就是全文翻译,但我不想这么做…...
2024/4/20 12:30:25
Dos批处理讲解-1
最近对于批处理技术的探讨比较热，也有不少好的批处理程序发布，但是如果没有一定的相关知识恐怕不容易看懂和理解这些批处理文件，也就更谈不上自己动手编写了，古语云：“授人以鱼，不如授人以渔。”因为网上好像并没有一个比较完整的教材,所以抽一点时间写了这片<<简…...
2024/4/21 9:59:41
基于C#的Kalman滤波器
最近项目用到了kalman滤波器，由于是.NET平台的，原来的OpenCV的那套东西不能用了，还好灵光乍现，开源就是好啊！花了一个小时将CvKalman用C#进行实现，解决了！其中的Matrix运算采用了CSDN下载频道的“C#矩阵库”。using System; using System.Collections.Generic; using …...
2024/4/27 7:37:23
Win7下 VC6 Visual Assist X兼容性问题
一、VC6的兼容性问题：无法使用“打开”命令解决方法：百度filetool，不多说二、Visual Assist X无法使用回车、上下左右选择解决办法:升级至1738版本，CSDN下载频道有破解版...
2024/4/20 17:56:43
Python批量下载Bilibili(B站)1080P60fps视频-pip打包安装
BiliUtilBilibili.com（B站）视频下载工具包 Github源码地址：https://github.com/wolfbolin/BiliUtil 声明：该内容仅供学习参考，请勿用于商业目的帮助信息请看到第三章，更新日志请看到第四章一、安装方式请使用pip安装该包：pip install BiliUtil 若使用视频下载功能，请…...
2024/4/20 17:56:42
Spark(这里只谈批处理)必知
1.what这个技术是什么官方文档定义Apache Spark™ is a unified analytics engine for large-scale data processing. 就是大数据分析引擎，至于unified（统一），应该是因为下图。Combine SQL, streaming, and complex analytics.Spark powers a stack of libraries including…...
2024/4/20 17:56:41
动易swCMS6.5网站后台频道管理菜单可编辑技术
动易swCMS6.5网站后台频道管理菜单可编辑技术在动易cms6.5网站后台添加一个内部频道后，则后台框架左栏的管理菜单也相应增加该频道管理菜单。如何实现呢？在还没有对文件Admin_Index_Left.asp进行分析前我还以为是使用JS+XML技术来实现后台菜单的编辑，现在经过分析，其实…...
2024/4/20 17:56:40
批处理设计知识
最近对于批处理技术的探讨比较热，也有不少好的批处理程序发布，但是如果没有一定的相关知识恐怕不容易看懂和理解这些批处理文件，也就更谈不上自己动手编写了，古语云：“授人以鱼，不如授人以渔。”因为网上好像并没有一个比较完整的教材,所以抽一点时间写了这片<<简…...
2024/4/20 17:56:40
.net下载优酷1080P视频
其实流程大致是：调用飞驴下载API+js解析+文件下载+调用flvBind合并这样一个流程而已_(:з」∠)_ 貌似是不用太多的说明。。嗯。。起先的需求是从优酷上下载一些视频不过网络上的各种软件甚至是优酷自己的APP 都没有提供高清视频下载的功能而且1080P视频本身对于优酷就是一种…...
2024/4/20 17:56:38
BAT 批处理脚本教程
BAT 批处理脚本教程第一章批处理基础第一节常用批处理内部命令简介批处理定义顾名思义批处理文件是将一系列命令按一定的顺序集合为一个可执行的文本文件其扩展名为BAT或者CMD。这些命令统称批处理命令。小知识可以在键盘上按下Ctrl+C组合键来强行终止一个批处理的执行…...
2024/4/20 17:56:37

DOS批处理高级教程：第七章 DOS批处理编程高级技巧(转)

相关文章

最新文章