bat命令之for命令详解

2024/5/2 10:21:39

 

______________版主提醒____________________________

　　为了避免影响技术讨论、提高看帖的舒适性，请大家不要在此帖下跟
无实质内容的口水帖，特别是纯顶、纯支持、纯感谢、路过之类的帖子，
管理人员将不定期清理此类回帖，请大家多参与讨论少灌水，与人方便，
终将给自己带来方便，谢谢合作。
________________________________________________________________

　　批处理是一门简单的脚本语言，虽然不能独当一面，但是，若作为工作中的辅助工具，绝对会让大家有随用随写、称心如意的畅快感。

　　和其他语言相比，批处理语言有其先天性的优势：

　　1、系统自带，无需另行安装；
　　2、命令少，语句简洁，上手非常快；
　　3、编写出来的脚本小巧玲珑，随写随用；

　　但是，因为它以命令行方式工作，操作多有不便，在图形界面大行其道的windows世界里，多多少少会让大众望而却步；就算是对命令行有好感的新手，面对微软有如天书的帮助文件，很多人也会败下阵来，因此，论坛里很多会员也发出了编写系统的批处理教程的呼声。

　　编写系统的批处理新手教程，一直是论坛管理层讨论的热点问题，但是，各位管理人员大多都有工作在身，而系统的教程涉及的面是如此之广，面对如此浩大的工程，仅凭一两个人的力量，是难以做好的，因此，本人退而求其次，此次发布的教程，以专题的形式编写，日后人手渐多之后，再考虑组织人力编写全面的教程。

　　之所以选择最难的for，一是觉得for最为强大，是大多数人最希望掌握的；二是若写其他命令教程，如果没有for的基础，展开来讲解会无从下手；三是for也是批处理中最复杂最难掌握的语句，把它攻克了，批处理的学习将会一片坦途。

　　这次的for语句系列教程，打算按照for语句的5种句式逐一展开，在讲解 for /f 的时候，会穿插讲解批处理中一个最为关键、也是新手最容易犯错的概念：变量延迟，大纲如下：

一 前言
二 for语句的基本用法
三 for /f （含变量延迟）
四 for /r
五 for /d
六 for /l

　　遵照 yibantiaokuan 的建议，在顶楼放出此教程的txt版本、word版本和pdf版本，以方便那些离线浏览的会员。

　　由于本人水平有限，本教程尚存在不少错误，承蒙各位热心会员的关注，一些已知的错误在（对“批处理for语句从入门到精通”的找茬行动：http://bbs.bathome.net/thread-14068-1-1.html）这个帖子中被指出，并在陆续更新之中，请各位务必注意指正帖中指出的错误之处，并欢迎各位在那个帖子中把本教程中的错误一一挑出，本人将抽空更新教程中有误的地方。

下载地址：
http://pan.baidu.com/share/link?shareid=3613722265&uk=1124163200
6

评分人数

 
    • pandeng603: 非常易懂，很有帮助技术 + 1
    • xinali: jishu技术 + 1
    • flaven: 谢谢！技术 + 1
    • geno: 非常有帮助。技术 + 1
    • mstsc: 讲的很透彻清楚，对我这样的新手很有帮助。 ...技术 + 1
收藏分享
尺有所短寸有所长，学好批处理没商量；
考虑问题复杂化，解决问题简洁化。
心在天山，身老沧州。
 
   
   
namejm

荣誉版主

Rank: 8Rank: 8

帖子
1352 
积分
4487 
技术
77  
捐助
501  
注册时间
2007-10-25 
2楼
 
 发表于 2008-10-16 21:10 | 只看该作者
 
 
 

一、前言

　　在批处理中，for是最为强大的命令语句，它的出现，使得解析文本内容、遍历文件路径、数值递增/递减等操作成为可能；配合if、call、goto等流程控制语句，更是可以实现脚本复杂的自动化、智能化操作；合理使用for语句，还能使代码大为简化，免除各位编写大量重复语句之苦。而能否熟练使用for语句，已经成为衡量一个人批处理水平高低最主要的标准。

　　在这个系列教程中，我将通过实际应用中频繁出现的例子，带领大家步入for语句的神奇之门，一步步迈向for语句的魔幻殿堂，使得大家在实际的应用中，能独立写出简洁高效的代码，在批处理的世界里自由驰骋。

　　注意：以下的讲解，都是基于简体中文版Windows XP Pro SP3的操作系统环境。
 
尺有所短寸有所长，学好批处理没商量；
考虑问题复杂化，解决问题简洁化。
心在天山，身老沧州。
 
 

TOP

   
namejm

荣誉版主

Rank: 8Rank: 8

帖子
1352 
积分
4487 
技术
77  
捐助
501  
注册时间
2007-10-25 
3楼
 
 发表于 2008-10-16 21:10 | 只看该作者
 
 
 

二、for语句的基本用法[2008.11.9更新]

本帖最后由 Hello123World 于 2012-6-16 13:27 编辑

　　正如色彩缤纷的七彩光芒是由红绿蓝三原色构成的一样，最复杂的for语句，也有其基本形态，它的模样是这样的：
    （以下3条代码修改由qzwqzw提供）　　在cmd窗口中：
  1. FOR %variable IN (set) DO command [command-parameters]
复制代码
在批处理文件中：
  1. FOR %%variable IN (set) DO command [command-parameters]，
复制代码

    具体例子：
  1. For %i in (1 2 3) do @echo %i
复制代码
之所以要区分cmd窗口和批处理文件两种环境，是因为在这两种环境下，命令语句表现出来的行为虽然基本一样，但是在细节上还是稍有不同，最明显的一个差异就是：在cmd窗口中，for之后的形式变量I必须使用单百分号引用，即%I；而在批处理文件中，引用形式变量I必须使用双百分号，即%%I。为了方便起见，若不是特别强调，以下的讲解都以批处理文件环境为例。

　　我们先来看一下for语句的基本要素都有些什么：
　　1、for、in和do是for语句的关键字，它们三个缺一不可；
　　2、%%I是for语句中对形式变量的引用，就算它在do后的语句中没有参与语句的执行，也是必须出现的；
　　3、in之后，do之前的括号不能省略；
　　4、command1表示字符串或变量，command2表示字符串、变量或命令语句；

　　现在，你可能已经会写一个简单的for语句了，比如：
[code1]
  1. @echo off
  2. for %%I in (bbs.bathome.net) do echo %%I
  3. pause
复制代码
保存为批处理文件并执行，将会在弹出的批处理窗口中看到这样的信息：
[result1]
bbs.bathome.net
请按任意键继续...

　　很快地，你会觉得这个for语句是如此的简单，简单到你丝毫感受不出它的强大：这个for语句，和我直接用echo语句没什么两样啊！

　　是的，演示代码永远都只是演示而已，就像大多数高级语言的教科书一样，在引导新手学习的时候，基本上都是千篇一律地告诉大家如何编写一个能显示 hello world! 的窗口，从这些演示代码中，你看不到它们具有多少实用性，你只是感到有点好奇：咦，居然弹出了一个窗口？片刻之后，你就会觉得索然无味。

　　那好吧，为了让大家对for更加感兴趣，我们先来分析一下for语句的一些注意事项，之后，再让大家看看更为强大的for语句实例。
　　
　　1、for语句的形式变量I，可以换成26个字母中的任意一个，这些字母会区分大小写，也就是说，%%I和%%i会被认为不是同一个变量；形式变量I还可以换成其他的字符，但是，为了不与批处理中的%0～%9这10个形式变量发生冲突，请不要随意把%%I替换为%%0 ～%%9中的任意一个；
　　2、in和do之间的command1表示的字符串或变量可以是一个，也可以是多个，每一个字符串或变量，我们称之为一个元素，每个元素之间，用空格键、跳格键、逗号、分号或等号分隔；
　　3、for语句依次提取command1中的每一个元素，把它的值赋予形式变量I,带到do后的command2中参与命令的执行；并且每次只提取一个元素，然后执行一次do后的命令语句，而无论这个元素是否被带到command2中参与了command2的运行；当执行完一次do后的语句之后，再提取command1中的下一个元素，再执行一次command2，如此循环，直到command1中的所有元素都已经被提取完毕，该for语句才宣告执行结束；
其中，第3点是最为关键的，它描述了for语句的执行过程，是for语句的精髓所在，大家一定要牢记这一条，才能深刻理解更为复杂的for流程。

　　有了以上的基础，我们再来看一个例子，这个例子修改了[code1]的部分内容，结果将大不一样：
[code2]
  1. @echo off
  2. for %%I in (bbs,bathome,net) do echo %%I
  3. pause
复制代码
和[code1]的执行结果[result1]相比，[result2]发生了如下变化：

　　1、显示结果分成了3行（不算最后一行中文提示）；
　　2、每一行都从逗号处被切分；

　　如果把 bbs.bathome.net 这个字符串中的点号换为空格、跳格或等号，执行结果将和example2的执行结果别无二致。

　　现在，我们来分析一下[code2]代码中for语句的执行过程：

　　首先，for语句以逗号为分隔符，把 bbs,bathome.net 这个字符串切分成三个元素：bbs、bathome和cn，由此决定了do后的语句将会被执行3次；
　　然后，第一次执行过程是这样的：先把 bbs 这个字符串作为形式变量I的值，带入do后的语句中加以执行，也就是执行 echo %%I 语句，此时的I值为bbs，因此，第一次执行的结果，将会在屏幕上显示bbs这个字符串；第二次执行和第一次执行的过程是一样的，只不过此时I的值已经被替换为command1中的第二个元素了，也就是 bathome 这个字符串；如此循环，当第三次echo执行完毕之后，整条for语句才算执行完毕，此时，将执行下一条语句，也就是pause命令。

　　其实，这个例子只比上一个例子多了一点花样，有趣了那么一点点：一条for语句的执行结果居然被分成了3行！

　　为了让大家见识一下for的真正威力，本人绞尽脑汁，翻帖无数，不得要领，万般无奈之下，只好亮出了尘封在箱底多年的一段代码：检测当前硬盘都有哪些分区^_^
[code3]
  1. @echo off
  2. set str=c d e f g h i j k l m n o p q r s t u v w x y z
  3. echo 当前硬盘的分区有：
  4. for %%i in (%str%) do if exist %%i: echo %%i:
  5. pause
复制代码
这段代码能检测硬盘都有哪些分区，包括U盘和移动硬盘的分区，但是，当光驱中有盘的时候，也会被列出来，这是本代码的一个缺憾，在以后的讲解中，我将向大家讲述如何消除这个瑕疵，敬请关注本系列的后续章节。

　　高级应用：

　　想知道当前目录下都有哪些文件吗？请用下面的代码：
  1. @echo off
  2. for %%i in (*.*) do echo "%%i"
  3. pause
复制代码
想列出当前目录下所有的文本文件吗？请用下面的代码：
  1. @echo off
  2. for %%i in (*.txt) do echo "%%i"
  3. pause
复制代码
想列出只用两个字符作为文件名的文本文件吗？(hello123world注:实际上这个代码是输出少于或等于两个字符作为文件名的文本文件)请用下面的代码：
  1. @echo off
  2. for %%i in (??.txt) do echo "%%i"
  3. pause
复制代码
题外话：

　　1、列出当前目录下各种文件的方法，最简单的还是用dir命令，但是，从以上代码中，各位可以加深对for语句执行流程的理解（用到了通配符*和?）；
　　2、注意：以上代码不能列出含有隐藏或系统属性的文件；（hello123world注：这里其实有一个很有趣的现象，windows中的系统文件一般具备两种属性——隐藏和系统；但是你如果测试的话就会发现，加上+s属性，但是不加+h的文件是可以被简单的for显示出来的。
例如：
  1. @echo off
  2. attrib +s 1.txt
  3. For  %%i in (*.txt) do Echo %%i
  4. pause
复制代码
这里的1.txt在结果中显示出来了。所以“以上代码不能列出含有隐藏或系统属性的文件”是不准确的，而因该说成“以上代码不能列出含有隐藏属性的文件”）

　　练习：用for语句建立test1.txt、test2.txt和test3.txt三个文本文件。

　　更全面的练习请看这个帖子：for语句从入门到精通配套练习题
5

评分人数

 
    • wangx: 乐于助人技术 + 1
    • 怪怪的僵尸: 乐于助人技术 + 1
    • raymai97: 乐于助人技术 + 1
    • aa65535: 乐于助人技术 + 1
    • pusofalse: 感谢你为新手提供的便利。 + 1
尺有所短寸有所长，学好批处理没商量；
考虑问题复杂化，解决问题简洁化。
心在天山，身老沧州。
 
 

TOP

   
namejm

荣誉版主

Rank: 8Rank: 8

帖子
1352 
积分
4487 
技术
77  
捐助
501  
注册时间
2007-10-25 
4楼
 
 发表于 2008-10-16 21:10 | 只看该作者
 
 
 

三、文本解析显神威：for /f 用法详解[2009.2.10更新]

本帖最后由 Hello123World 于 2012-6-16 13:40 编辑

　　　　前言

　　for /f 是个十分强大的家伙。

　　如果说，for语句是批处理中最强大的语句的话，那么，for /f 就是精华中的精华。

　　for /f 的强大，和它拥有众多的开关密切相关。因为开关众多，所以用法复杂，本章将分成若干小节，为大家逐一介绍强大的 for /f 语句。

　　　　（一） 为解析文本而生：for /f 的基本用法

　　所有的对象，无论是文件、窗体、还是控件，在所有的非机器语言看来，无外乎都是形如"c:\test.txt"、"CWnd"之类的文本信息；而所有的对象，具体的如ini文件中的某条配置信息、注册表中的某个键值、数据库中的某条记录……都只有转化为具有一定格式的文本信息，方可被代码识别、操控。可以说，编程的很大一部分工作，都是在想方设法绞尽脑汁如何提取这些文本信息。

　　而提取文本信息，则是for /f的拿手好戏：读取文件内容；提取某几行字符；截取某个字符片段；对提取到的内容再切分、打乱、杂糅……只要你所能想到的花样，for /f 都会想方设法帮你办到，因为，for /f 就是被设计成专门用于解析文本的。

　　先来看个例子。

　　假如有个文本文件test.txt，内容如下：
[txt1]
论坛的目标是：不求最大，但求最好，做最实用的批处理论坛。
论坛地址：bbs.bathome.net。
这里是：新手晋级的福地，高手论剑的天堂。
那么，将如下代码保存为test.cmd，并放在test.txt同一目录下运行，将会在屏幕上原样显示test.txt的内容：
[code4]
  1. @echo off
  2. for /f %%i in (test.txt) do echo %%i
  3. pause
复制代码
这段代码，主要是让你树立这样一种观念：读取文本文件的内容（qzwqzw注：改为“逐行分析文本文件的内容”，因为读取文本文件内容的方法命令有很多，比如重定向输入，又比如type/more/find/sort等命令），请使用 for /f 语句！

　　进阶话题：for /f 语句是把整个test.txt一次性显示出来的？

　　在这段代码中，虽然执行结果是把test.txt中的所有内容都显示出来了，貌似 for /f 语句是把整个test.txt一次性显示到屏幕上，实际上并非如此。

　　无论for语句做何种变化，它的执行过程仍然遵循基本的for流程：依次处理每个元素，直到所有的元素都被处理为止。只不过在for /f语句中，这里的元素是指文件中的每一行，也就是说，for /f 语句是以行为单位处理文本文件的。这是一条极为重要的规则，在上一章中也强调过它的重要性，希望在接下来的学习过程中，你能时刻牢记这一原则，那么，很多问题将会迎刃而解。以下是验证这一说法的演示代码（在[code4]的基础上添加了&pause语句）：
[code5]
  1. @echo off
  2. for /f %%i in (test.txt) do echo %%i&pause
  3. pause
复制代码
（二） 切分字符串的利器：delims=

　　也许你对[code4]这段代码不屑一顾：不就是把test.txt的内容显示出来了么？好像用处不大啊。

　　好吧，我们来玩个魔术。

　　还是[txt1]这段文本，把[code4]改造一下：
[code6]
  1. @echo off
  2. for /f "delims=，" %%i in (test.txt) do echo %%i
  3. pause
复制代码
再次运行test.cmd，看到什么变化了吗？！
[result2]
  1. 论坛的目标是：不求最大
  2. 论坛地址：bbs.bathome.net。
  3. 这里是：新手晋级的福地
  4. 请按任意键继续...
复制代码
结果，你惊奇地发现，每行第一个逗号之后的所有内容都不见了（如果有不存在逗号的行，则保留原样），也就说，你成功地提取到了每行第一个逗号之前的所有内容！

　　试想一下，这段代码会有什么用呢？

　　如果别人给了你一个软件清单，每行都是"英文软件名（逗号）中文软件名"的格式，而你却只想保留英文名的时候，这段代码将是多么有用啊！再假设，有这么一个IP文件，第一列是数字格式的IP地址，第二列是具体的空间地址，列与列之间用逗号分隔，而你想提取其中数字格式的IP，呵呵，我不说你也知道该怎么办了吧？

　　要是文本内容不是以逗号分隔，而是以其他符号分隔，那么，把"delims=,"的逗号换成相应的符号就可以了。

　　在这里，我们引入了一个新的开关："delims=，"，它的含义是：以逗号作为被处理的字符串的分隔符号。

　　在批处理中，指定分隔符号的方法是：添加一个形如 "delims=符号列表" 的开关，这样，被处理的每行字符串都会被符号列表中罗列出来的符号切分开来。

　　需要注意的是：如果没有指定"delims=符号列表"这个开关，那么，for /f 语句默认以空格键或跳格键作为分隔符号。请把[txt1]中不同位置上的标点符号改为空格或跳格，再运行[code4]试试。

　　进阶话题：如果我要指定的符号不止一个，该怎么办？

　　在上面的讲解中，我提到了指定分隔符号的方法：添加一个形如"delims=符号列表"的开关。不知道你注意到没有，我的说法是"符号列表"而非"符号"，这是大有讲究的，因为，你可以一次性指定多个分隔符号！

　　还是以[txt1]为例，把[code6]再改造一下：
[code7]
  1. @echo off
  2. for /f "delims=.，" %%i in (test.txt) do echo %%i
  3. pause
复制代码
结果显示：
[result3]
  1. 论坛的目标是：不求最大
  2. 论坛地址：bbs
  3. 这里是：新手晋级的福地
  4. 请按任意键继续...
复制代码
这样，第一个点号或第一个逗号之前的内容都被提取出来了。

　　[code7]的执行过程是：逐行读取test.txt中的内容，以点号和逗号切分每一行的内容（不存在点号和逗号的行，则不再切分，为了描述的方便，我们把被点号或逗号切分的一个一个的字符串片段，称之为节），然后，for /f 会提取第一节的内容作为最终结果，显示在屏幕上。需要注意的是，在这里，所有行的字符串被切分成了两个以上的节，但是，[code7]的代码只会提取第一节字符串的内容，因为 for /f 语句默认只提取第一节的符串。


　　　　（三） 定点提取：tokens=

　　上一节在讲解 delims= 的时候，我一再强调 for /f 默认只能提取到第一节的内容，现在我们来思考一个问题：如果我要提取的内容不在第一节上，那怎么办？

　　这回，就该轮到 tokens= 出马了。

　　tokens= 后面一般跟的是数字，如 tokens=2，也可以跟多个，但是每个数字之间用逗号分隔，如 tokens=3,5,8，它们的含义分别是：提取第2节字符串、提取第3、第5和第8节字符串。注意，这里所说的“节”，是由 delims= 这一开关划分的，它的内容并不是一成不变的。

　　下面来看一个例子：
[txt2]
  1. 尺有所短，寸有所长，学好批处理没商量，考虑问题复杂化，解决问题简洁化。
复制代码
对[txt2]这段文本，假设它们保存在文件test.txt中，如果我想提取“学好批处理没商量”这句话，该如何写代码呢？

　　我们稍微观察一下[txt2]就会发现，如果以逗号作为切分符号，就正好可以把“学好批处理没商量”化为单独的一“节”，结合上一节的讲解，我们知道，"delims=，" 这个开关是不可缺少的，而要提取的内容在以逗号切分的第3节上，那么，tokens= 后面的数字就应该是3了，最终的代码如下：
[code8]
  1. @echo off
  2. for /f "delims=， tokens=3" %%i in (test.txt) do echo %%i
  3. pause
复制代码
如果我们现在要提取的不只一个“节”，而是多个，那又怎么办呢？比如，要提取以逗号切分的第2节和第5节字符串，是写成这样吗？
[code9]
  1. @echo off
  2. for /f "delims=， tokens=2,5" %%i in (test.txt) do echo %%i
  3. pause
复制代码
运行批处理后发现，执行结果只显示了第2节的内容。

　　原来，echo 后面的 %%i 只接收到了 tokens=2,5 中第一个数值2所代表的那个字符串，而第二个数值5所代表的字符串因为没有变量来接收，所以就无法在执行结果中显示出来了。

　　那么，要如何接收 tokens= 后面多个数值所指代的内容呢？

　　for /f 语句对这种情况做如下规定：

　　如果 tokens= 后面指定了多个数字，如果形式变量为%%i，那么，第一个数字指代的内容用第一个形式变量%%i来接收，第二个数字指代的内容用第二个形式变量%%j来接收，第三个数字指代的内容用第三个形式变量%%k来接收……第N个数字指代的内容用第N个形式变量来接收，其中，形式变量遵循字母的排序，第N个形式变量具体是什么符号，由第一个形式变量来决定：如果第一个形式变量是%%i，那么，第二个形式变量就是%%j；如果第一个形式变量用的是%%x，那么，第二个形式变量就是%%y。

　　现在回头去看[code9]，你应该知道如何修改才能满足题目的要求了吧？修改结果如下：
[code10]
  1. @echo off
  2. for /f "delims=， tokens=2,5" %%i in (test.txt) do echo %%i %%j
  3. pause
复制代码
如果有这样一个要求：显示[txt2]中的内容，但是逗号要替换成空格，如何编写代码？

　　结合上面所学的内容，稍加思索，你可能很快就得出了答案：
[code11]
  1. @echo off
  2. for /f "delims=， tokens=1,2,3,4,5" %%i in (test.txt) do echo %%i %%j %%k %%l %%m
  3. pause
复制代码
写完之后，你可能意识到这样一个问题：假如要提取的“节”数不是5，而是10，或者20，或者更多，难道我也得从1写到10、20或者更多吗？有没有更简洁的写法呢？

　　答案是有的，那就是：如果要提取的内容是连续的多“节”的话，那么，连续的数字可以只写最小值和最大值，中间用短横连接起来即可，比如 tokens=1,2,3,4,5 可以简写为 tokens=1-5 。

　　还可以把这个表达式写得更复杂一点：tokens=1,2-5，tokens=1-3,4,5，tokens=1-4,5……怎么方便就怎么写吧。

　　大家可能还看到一种比较怪异的写法：
[code12]
  1. @echo off
  2. for /f "delims=， tokens=1,*" %%i in (test.txt) do echo %%i %%j
  3. pause
复制代码
结果，第一个逗号不见了，取代它的是一个空格符号，其余部分保持不变。

　　其中奥妙就在这个星号上面。

　　tokens=后面所接的星号具备这样的功能：字符串从左往右被切分成紧跟在*之前的数值所表示的节数之后，字符串的其余部分保持不变，整体被*所表示的一个变量接收。

　　理论讲解是比较枯燥的，特别是为了严密起见，还使用了很多限定性的修饰词，导致句子很长，增加了理解的难度，我们还是结合[code12]来讲解一下吧。

　　[txt2] 的内容被切分，切分符号为逗号，当切分完第一节之后，切分动作不再继续下去，因为 tokens=1,* 中，星号前面紧跟的是数字1；第一节字符串被切分完之后，其余部分字符串不做任何切分，整体作为第二节字符串，这样，[txt2]就被切分成了两节，分别被变量%%i和变量%%j接收。

　　以上几种切分方式可以结合在一起使用。不知道下面这段代码的含义你是否看得懂，如果看不懂的话，那就运行一下代码，然后反复揣摩，你一定会更加深刻地理解本节所讲解的内容的：
[code13]
  1. @echo off
  2. for /f "delims=， tokens=1,3-4,*" %%i in (test.txt) do echo %%i %%j %%k %%l
  3. pause
复制代码
（四） 跳过无关内容，直奔主题：skip=n

　　很多时候，有用的信息并不是贯穿文本内容的始终，而是位于第N行之后的行内，为了提高文本处理的效率，或者不受多余信息的干扰，for /f 允许你跳过这些无用的行，直接从第N+1行开始处理，这个时候，就需要使用参数 skip=n，其中，n是一个正整数，表示要跳过的行数。例如：
[code14]
  1. @echo off
  2. for /f "skip=2" %%i in (test.txt) do echo %%i
  3. pause
复制代码
这段代码将跳过头两行内容，从第3行起显示test.txt中的信息。


　　　　（五） 忽略以指定字符打头的行：eol=

　　在cmd窗口中敲入：for /?，相关的解释为：
eol=c           - 指一个行注释字符的结尾(就一个)
FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k
    会分析 myfile.txt 中的每一行，忽略以分号打头的那些行……

　　第一条解释狗屁不通，颇为费解：行注释字符的结尾是什么意思？“(就一个)”怎么回事？结合第二条解释，才知道eol有忽略指定行的功能。但是，这两条解释是互相矛盾的：到底是忽略以指定字符打头的行，还是忽略以指定字符结尾的行？

　　实践是检验真理的唯一标准，还是用代码来检验一下eol的作用吧：
[code15]
  1. @echo off
  2. for /f "eol=;" %%i in (test.txt) do echo %%i
  3. pause
复制代码
结果，那些以分号打头的行没有显示出来。

　　由此可见，第二条解释是正确的，eol= 的准确含义是：忽略以指定字符打头的行。而第一条的“结尾”纯属微软在信口开河。

　　那么，“(就一个)”又作何解释呢？

　　试试这个代码：
[code16]
  1. @echo off
  2. for /f "eol=,;" %%i in (test.txt) do echo %%i
  3. pause
复制代码
此时，屏幕上出现 此时不应有 ;"。 的报错信息。可见，在指定字符的时候，只能指定1个——在很多时候，我对这样的设计颇有微词而又无可奈何：为什么只能指定1个而不是多个？要忽略多个还得又是if又是findstr加管道来多次过滤，那效率实在太低下了——能用到的功能基本上都提供，但是却又做不到更好，批处理，你的功能为什么那么弱？

　　不知道大家注意到没有，如果test.txt中有以分号打头的行，那么，这些行在代码[code14]的执行结果中将凭空消失。

　　原来，for /f 语句是默认忽略以分号打头的行内容的，正如它默认以空格键或跳格键作为字符串的切分字符一样。（hello123world注：eol=;这种默认设置，在delims=;时变得无效。）

　　很多时候，我们可以充分利用这个特点，比如，在设计即将用for读取的配置文件的时候，可以在注释文字的行首加上分号，例如在编写病毒文件查杀代码的时候，可以通过for语句来读取病毒文件列表，那么，病毒文件列表.ini这个配置文件可以这样写：
;以下是常见的病毒文件，请见一个杀一个^_^
;copyleft:没有
qq.exe
msn.exe
iexplore.exe


　　如果要取消这个默认设置，可选择的办法是：

　　1、为eol=指定另外一个字符；
　　2、使用 for /f "eol=" 语句，也就是说，强制指定字符为空，就像对付delims=一样。


　　　　（六）如何决定该使用 for /f 的哪种句式？（兼谈usebackq的使用）

　　for /f %%i in (……) do (……) 语句有好几种变形语句，不同之处在于第一个括号里的内容：有的是用单引号括起来，有的是用双引号包住，有的不用任何符号包裹，具体格式为：

　　1、for /f %%i in (文件名) do (……)
　　2、for /f %%i in ('命令语句') do (……)
　　3、for /f %%i in ("字符串") do (……)


　　看到这里，我想很多人可能已经开始犯了迷糊了：如果要解决一个具体问题，面对这么多的选择，如何决定该使用哪一条呢？

　　实际上，当我在上面罗列这些语句的时候，已经有所提示了，不知道你是否注意到了。

　　如果你一时无法参透其中奥妙，那也无妨，请听我一一道来便是。

　　1、当你希望读取文本文件中的内容的话，第一个括号中不用任何符号包裹，应该使用的是第1条语句；例如：你想显示test.txt中的内容，那么，就使用 for /f %%i in (test.txt) do echo %%i；
　　2、当你读取的是命令语句执行结果中的内容的话，第一个括号中的命令语句必须使用单引号包裹，应该使用的是第2条语句；例如：你想显示当前目录下文件名中含有test字符串的文本文件的时候，应该使用 for /f %%i in ('dir /a-d /b *test*.txt') do echo %%i 这样的语句；
　　3、当你要处理的是一个字符串的时候，第一个括号中的内容必须用双引号括起来，应该是用的是第3条语句；例如：当你想把bbs.bathome.net这串字符中的点号换为短横线并显示出来的话，可以使用 for /f "delims=. tokens=1-3" %%i in ("bbs.bathome.net") do echo %%i-%%j-%%k 这样的语句。

　　很显然，第一个括号里是否需要用符号包裹起来，以及使用什么样的符号包裹，取决于要处理的对象属于什么类型：如果是文件，则无需包裹；如果是命令语句，则用单引号包裹；如果是字符串，则使用双引号括起来。

　　当然，事情并不是绝对如此，如果细心的你想到了批处理中难缠的特殊字符，你肯定会头大如斗。

　　或许你头脑中灵光一闪，已经想到了一个十分头痛的问题：在第1条语句中，如果文件名中含有空格或&，该怎么办？

　　照旧吗？

　　拿个叫 test 1.txt 的文件来试试。

　　你很快写好了代码，新建文件-->码字-->保存为批处理，前后费时不到1分钟：
[code17]
  1. @echo off
  2. for /f %%i in (test 1.txt) do echo %%i
  3. pause
复制代码
你兴冲冲地双击批处理，运行后，屏幕上出现了可耻的报错信息：系统找不到文件 test 。

　　当你把 test 1.txt 换成 test&1.txt 后，更怪异的事情发生了：CMD窗口在你眼前一闪而过，然后，优雅地消失了。

　　你可能觉得自己的代码写错了某些符号，你再仔细的检查了一次，确认没有笔误，然后，你再次双击批处理，结果问题照旧；你开始怀疑其他程序对它可能有影响，于是关掉其他窗口，再运行了一次，问题依旧；你不服气地连续运行了好几次，还是同样的结果。

　　怪哉！

　　你一拍大腿，猛然想起了一件事：当路径中含有特殊字符的时候，应该使用引号把路径括起来。对，就是它了！

　　但是，当你把代码写出来之后，你很快就焉了：for /f %%i in ("test 1.txt") do echo %%i，这不就是上面提到的第3条 for /f 命令的格式吗？批处理会把 test 1.txt 这个文件名识别为字符串啊！

　　你百无聊赖地在CMD窗口中输入 for /? ，并重重地敲下了回车，漫无目的地在帮助信息中寻找，希望能找到点什么。

　　结果还真让你到了点什么。

　　你看到了这样的描述：
        usebackq        - 指定新语法已在下类情况中使用:
                          在作为命令执行一个后引号的字符串并且一个单
                          引号字符为文字字符串命令并允许在 filenameset
                          中使用双引号扩起文件名称。


　　但是，通读一遍之后，你却如坠五里雾中，不知所云。

　　还好，下面有个例子，并配有简单的说明：

      FOR /F "usebackq delims==" %i IN (`set`) DO @echo %i
    会枚举当前环境中的环境变量名称。


　　你仔细对比了for /f语句使用usebackq和不使用usebackq时在写法上的差别，很快就找到了答案：当使用了usebackq之后，如果第一个括号中是一条命令语句，那么，就要把单引号'改成后引号`（键盘左上角esc键下面的那个按键，与~在同一键位上）。

　　回过头去再看那段关于usebackq的描述，字斟句酌，反复揣摩，终于被你破译了天机：usebackq 是一个增强型参数，当使用了这个参数之后，原来的for语句中第一个括号内的写法要做如下变动：如果第一个括号里的对象是一条命令语句的话，原来的单引号'要改为后引号`；如果第一个括号里的对象是字符串的话，原来的双引号"要改为单引号'；如果第一个括号里的对象是文件名的话，要用双引号"括起来。

　　验证一下，把[code17]改写成如下代码：
[code18]
  1. @echo off
  2. for /f "usebackq" %%i in ("test 1.txt") do echo %%i
  3. pause
复制代码
测试通过！

　　此时，你很可能会仰天长叹：Shit，微软这该死的机器翻译！

　　至于把[code17]代码中的空格换成&后，CMD窗口会直接退出，那是因为&是复合语句的连接符，CMD在预处理的时候，会优先把&前后两部分作为两条语句来解析，而不是大家想象中的一条完整的for语句，从而产生了严重的语法错误。因为牵涉到预处理机制问题，不属于本节要讨论的内容，在此不做详细讲解。

　　这个时候，我们会吃惊地发现，区区一条for语句，竟然有多达6种句型：

　　1、for /f %%i in (文件名) do (……)
　　2、for /f %%i in ('命令语句') do (……)
　　3、for /f %%i in ("字符串") do (……)
　　4、for /f "usebackq" %%i in ("文件名") do (……)
　　5、for /f "usebackq" %%i in (`命令语句`) do (……)
　　6、for /f "usebackq" %%i in ('字符串') do (……)

　　其中，4、5、6由1、2、3发展而来，他们有这样的对应关系：1-->4、2-->5、3-->6。

　　好在后3种情形并不常用，所以，牢牢掌握好前三种句型的适用情形就可以了，否则，要在这么多句型中确定选择哪一条语句来使用，还真有点让人头脑发懵。

　　至于 for /f 为什么要增加usebacq参数，我只为第4条语句找到了合理的解释：为了兼容文件名中所带的空格或&。它在第5、6条语句中为什么还有存在的必要，我也不是很明白，这有待于各位去慢慢发现。（hello123world注：这种解释虽然有点不靠谱，但也算一种解释，大家将就看看吧。启用usebackq选项的时候，“文件名”取代了“字符串”，那么“字符串”只好改变为“命令语句”，“命令语句”只好用后引号重新表示——简而言之，是“文件名”符号改变引起的蝴蝶效应。言外之意：usebackq除了在处理带空格的文件名时会用到外，根本就没有其它的出场机会和存在价值。）

[ 本帖最后由 namejm 于 2010-12-25 03:22 编辑 ]
7

评分人数

 
    • L-殇: 已将QQ,MSN,IE删除,现用GG与YY...技术 + 1
    • an410398183: 学习学习技术 + 1
    • wangx: 对我的帮助很大，谢谢分享技术 + 1
    • Cameron: 使用usebackq在拖放文件至cmd获取路径时很有 ...技术 + 1
    • bhutan: 那如果直接第4种情况就用后引号的话，第5、 ...技术 + 1
尺有所短寸有所长，学好批处理没商量；
考虑问题复杂化，解决问题简洁化。
心在天山，身老沧州。
 
 

TOP

   
namejm

荣誉版主

Rank: 8Rank: 8

帖子
1352 
积分
4487 
技术
77  
捐助
501  
注册时间
2007-10-25 
5楼
 
 发表于 2008-10-16 21:11 | 只看该作者
 
 
 

（七）变量延迟详解[2009.2.12更新]

　　变量延迟在for语句中起着至关重要的作用，不只是在for语句中，在其他的复合语句中，它也在幕后默默地工作着，为了突出它的重要性，本节内容在单独的楼层中发出来，希望引起大家的重视。

　　对于批处理新手而言，“变量延迟”这个概念很可能闻所未闻，但是，它却像一堵横亘在你前进道路上的无形高墙，你感受不到它的存在，但当你试图往前冲时，它会把你狠狠地弹回来，让你无法逾越、无功而返；而一旦找到了越过它的方法，你就会发现，在for的世界里，前面已经是一片坦途，而你对批处理的理解，又上升到了一个新的境界。

　　例如，你编写了这样一个代码：
[code19]
  1. @echo off
  2. set num=0&&echo %num%
  3. pause
复制代码
你的本意是想对变量num赋值之后，再把这个值显示出来，结果，显示出来的并不是0，而是显示：ECHO 处于关闭状态。

　　之所以会出错，是因为“变量延迟”这个家伙在作怪。

　　在讲解变量延迟之前，我们需要了解一下批处理的执行过程，它将有助于我们深入理解变量延迟。

　　批处理的执行过程是怎样的呢？

　　“自上而下，逐条执行”，我想，这个经典的说法大家都已经耳熟能详了，没事的时候倒着念，也还别有一番古韵呢^_^，但是，我想问大家的是，大家真的深刻地理解了这句话的含义了吗？

　　“自上而下”，这一条和我们本节的讲解关系不大，暂时略过不说，后一条，“逐条执行”和变量延迟有着莫大的干系，它是我们本节要关注的重点。

　　很多人往往认为一行代码就是一条语句，从而把“逐条执行”与“逐行执行”等同起来，这就大错特错了。

　　莫非“逐条执行”里暗藏着玄机？

　　正是如此。

　　“逐条”并不等同于“逐行”。这个“条”，是“一条完整的语句”的意思，并不是指“一行代码”。在批处理中，是不是一条完整的语句，并不是以行来论的，而是要看它的作用范围。

　　什么样的语句才算“一条完整的语句”呢？

　　1、在复合语句中，整个复合语句是一条完整的语句，而无论这个复合语句占用了多少行的位置。常见的复合语句有：for语句、if……else语句、用连接符&、||和&&连接的语句，用管道符号|连接的语句，以及用括号括起来的、由多条语句组合而成的语句块；
　　2、在非复合语句中，如果该语句占据了一行的位置，则该行代码为一条完整的语句。
　　例如：
[code20]
  1. @echo off
  2. set num=0
  3. for /f %%i in ('dir /a-d /b *.exe') do (
  4.     set /a num+=1
  5.     echo num 当前的值是 %num%
  6. )
  7. echo 当前目录下共有 %num% 个exe文件
  8. dir /a-d /b *.txt|findstr "test">nul&&(
  9.     echo 存在含有 test 字符串的文本本件
  10. )||echo 不存在含有 test 字符串的文本文件
  11. if exist test.ini (
  12.     echo 存在 test.ini 文件
  13. ) else echo 不存在 test.ini 文件
  14. pause
复制代码
上面的代码共有14行，但是只有完整的语句只有7条，它们分别是：

　　第1条：第1行的echo语句；
　　第2条：第2行的set语句；
　　第3条：第3、4、5、6行上的for复合语句；
　　第4条：第7行的echo语句；
　　第5条：第8、9、10行上用&&和||连接的复合语句；
　　第6条：第11、12、13行上的if……else复合语句；
　　第7条：第14行上的pause语句。

　　在这里，我之所以要花这么长的篇幅来说明一行代码并不见得就是一条语句，是因为批处理的执行特点是“逐条”执行而不是“逐行”执行，澄清了这个误解，将会更加理解批处理的预处理机制。

　　在代码“逐条”执行的过程中，cmd.exe这个批处理解释器会对每条语句做一些预处理工作，这就是批处理中大名鼎鼎的“预处理机制”。

　　预处理的大致情形是这样的：首先，把一条完整的语句读入内存中（不管这条语句有多少行，它们都会被一起读入），然后，识别出哪些部分是命令关键字，哪些是开关、哪些是参数，哪些是变量引用……如果代码语法有误，则给出错误提示或退出批处理环境；如果顺利通过，接下来，就把该条语句中所有被引用的变量及变量两边的百分号对，用这条语句被读入内存之就已经赋予该变量的具体值来替换……当所有的预处理工作完成之后，批处理才会执行每条完整语句内部每个命令的原有功能。也就是说，如果命令语句中含有变量引用（变量及紧邻它左右的百分号对），并且某个变量的值在命令的执行过程中被改变了，即使该条语句内部的其他地方也用到了这个变量，也不会用最新的值去替换它们，因为某条语句在被预处理的时候，所有的变量引用都已经被替换成字符串常量了，变量值在复合语句内部被改变，不会影响到语句内部的其他任何地方。

　　顺便说一下，运行代码[code20]之后，将在屏幕上显示当前目录下有多少个exe文件，是否存在含有 test 字符串的文本文件，以及是否存在 test.ini 这个文件等信息。让很多人百思不得其解的是：如果当前目录下存在exe文件，那么，有多少个exe文件，屏幕上就会提示多少次 "num 当前的值是 0" ，而不是显示1到N（N是exe文件的个数）。

　　结合上面两个例子，我们再来分析一下，为什么这两段代码的执行结果和我们的期望有一些差距。

　　在[code19]中，set num=0&&echo %num%是一条复合语句，它的含义是：把0赋予变量num，成功后，显示变量num的值。

　　虽然是在变量num被赋值成功后才显示变量num的值，但是，因为这是一条复合语句，在预处理的时候，&&后的%num%只能被set语句之前的语句赋予变量num的具体值来替换，而不能被复合语句内部、&&之前的set语句对num所赋予的值来替换，可见，此num非彼num。可是，在这条复合语句之前，我们并没有对变量num赋值，所以，&&之后的%num%是空值，相当于在&&之后只执行了 echo 这一命令，所以，会显示 echo 命令的当前状态，而不是显示变量num的值（虽然该变量的值被set语句改变了）。

　　在[code20]中，for语句的含义是：列举当前目录下的exe文件，每发现一个exe文件，变量num的值就累加1，并显示变量num的值。

　　看了对[code19]的分析之后，再来分析[code20]就不再那么困难了：第3、4、5行上的代码共同构成了一条完整的for语句，而语句"echo num 当前的值是 %num%"与"set /a num+=1"同处复合语句for的内部，那么，第4行上set改变了num的值之后，并不能对第5行上的变量num有任何影响，因为在预处理阶段，第5行上的变量引用%num%已经被在for之前就赋予变量num的具体值替换掉了，它被替换成了0（是被第2行上的set语句赋予的）。

　　如果想让代码[code19]的执行结果中显示&&之前赋予num的值，让代码[code20]在列举exe文件的时候，从1到N地显示exe文件的数量，那又该怎么办呢？

　　对代码[code19]，可以把用&&连接复合语句拆分为两条单独的语句，写成：
  1. @echo off
  2. set num=0
  3. echo %num%
  4. pause
复制代码
但是，这不是我们这次想要的结果。

　　对这两段代码都适用的办法是：使用变量延迟扩展语句，让变量的扩展行为延迟一下，从而获取我们想要的值。

　　在这里，我们先来充下电，看看“变量扩展”有是怎么一回事。

　　用CN-DOS里批处理达人willsort的原话，那就是：“在许多可见的官方文档中，均将使用一对百分号闭合环境变量以完成对其值的替换行为称之为“扩展（expansion）”，这其实是一个第一方的概念，是从命令解释器的角度进行称谓的，而从我们使用者的角度来看，则可以将它看作是引用（Reference）、调用（Call）或者获取（Get）。”（见：什么情况下该使用变量延迟？http://www.cn-dos.net/forum/viewthread.php?tid=20733）说得直白一点，所谓的“变量扩展”，实际上就是很简单的这么一件事情：用具体的值去替换被引用的变量及紧贴在它左右的那对百分号。

　　既然只要延迟变量的扩展行为，就可以获得我们想要的结果，那么，具体的做法又是怎样的呢？

　　一般说来，延迟变量的扩展行为，可以有如下选择：

　　1、在适当位置使用 setlocal enabledelayedexpansion 语句；
　　2、在适当的位置使用 call 语句。

　　使用 setlocal enabledelayedexpansion 语句，那么，[code19]和[code20]可以分别修改为：
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. set num=0&&echo !num!
  4. pause
复制代码
  1. @echo off
  2. set num=0
  3. setlocal enabledelayedexpansion
  4. for /f %%i in ('dir /a-d /b *.exe') do (
  5.     set /a num+=1
  6.     echo num 当前的值是 !num!
  7. )
  8. echo 当前目录下共有 %num% 个exe文件
  9. dir /a-d /b *.txt|findstr "test">nul&&(
  10.     echo 存在含有 test 字符串的文本本件
  11. )||echo 不存在含有 test 字符串的文本文件
  12. if exist test.ini (
  13.     echo 存在 test.ini 文件
  14. ) else echo 不存在 test.ini 文件
  15. pause
复制代码
使用第call语句，那么，[code19]和[code20]可以分别修改为：
  2. @echo off
  3. set num=0&&call echo %%num%%
  4. pause
复制代码
  2. @echo off
  3. set num=0
  4. for /f %%i in ('dir /a-d /b *.exe') do (
  5.     set /a num+=1
  6.     call echo num 当前的值是 %%num%%
  7. )
  8. echo 当前目录下共有 %num% 个exe文件
  9. dir /a-d /b *.txt|findstr "test">nul&&(
  10.     echo 存在含有 test 字符串的文本本件
  11. )||echo 不存在含有 test 字符串的文本文件
  12. if exist test.ini (
  13.     echo 存在 test.ini 文件
  14. ) else 不存在 test.ini 文件
  15. pause
复制代码
由此可见，如果使用 setlocal enabledelayedexpansion 语句来延迟变量，就要把原本使用百分号对闭合的变量引用改为使用感叹号对来闭合；如果使用call语句，就要在原来命令的前部加上 call 命令，并把变量引用的单层百分号对改为双层。 其中，因为call语句使用的是双层百分号对，容易使人犯迷糊，所以用得较少，常用的是使用 setlocal enabledelayedexpansion 语句（set是设置的意思，local是本地的意思，enable是能够的意思，delayed是延迟的意思，expansion是扩展的意思，合起来，就是：让变量成为局部变量，并延迟它的扩展行为）。

　　通过上面的分析，我们可以知道：

　　1、为什么要使用变量延迟？因为要让复合语句内部的变量实时感知到变量值的变化。
　　2、在哪些场合需要使用变量延迟语句？在复合语句内部，如果某个变量的值发生了改变，并且改变后的值需要在复合语句内部的其他地方被用到，那么，就需要使用变量延迟语句。而复合语句有：for语句、if……else语句、用连接符&、||和&&连接的语句、用管道符号|连接的语句，以及用括号括起来的、由多条语句组合而成的语句块。最常见的场合，则是for语句和if……else语句。
　　3、怎样使用变量延迟？
　　方法有两种：
　　① 使用 setlocal enabledelayedexpansion 语句：在获取变化的变量值语句之前使用setlocal enabledelayedexpansion，并把原本使用百分号对闭合的变量引用改为使用感叹号对来闭合；
　　② 使用 call 语句：在原来命令的前部加上 call 命令，并把变量引用的单层百分号对改为双层。 

　　“变量延迟”是批处理中一个十分重要的机制，它因预处理机制而生，用于复合语句，特别是大量使用于强大的for语句中。只有熟练地使用这一机制，才能在for的世界中如鱼得水，让自己的批处理水平更上一层楼。很多时候，对for的处理机制，我们一直是雾里看花，即使偶有所得，也只是只可意会难以言传。希望大家反复揣摩，多加练习，很多细节上的经验，是只有通过大量的摸索才能得到的。Good Luck！

　　本节内容在原理上参考了这篇文章：什么情况下该使用变量延迟？http://www.cn-dos.net/forum/viewthread.php?tid=20733，在本论坛中的地址是：http://bbs.bathome.net/viewthread.php?tid=2899

　　特别鸣谢：willsort。
 
尺有所短寸有所长，学好批处理没商量；
考虑问题复杂化，解决问题简洁化。
心在天山，身老沧州。
 
 

TOP

   
namejm

荣誉版主

Rank: 8Rank: 8

帖子
1352 
积分
4487 
技术
77  
捐助
501  
注册时间
2007-10-25 
6楼
 
 发表于 2008-10-16 21:11 | 只看该作者
 
 
 
四、翻箱倒柜遍历文件夹：for /r

　　（一）for /r 的作用及用法

　　按照帮助信息里文绉绉的说法，for /r 的作用是“递归”，我们换一个通俗一点的，叫“遍历文件夹”。

　　更详细的解释就是：在下面的语句中，如果“元素集合”中只是一个点号，那么，这条语句的作用就是：列举“目录”及其之下的所有子目录，对这些文件夹都执行“命令语句集合”中的命令语句。其作用与嵌套进 for /f 复合语句的 "dir /ad /b /s 路径" 功能类似。如果省略了“目录”，将在当前目录下执行前面描述的操作。
for /r 目录 %%i in (元素集合) do 命令语句集合

　　先来个代码增强一下印象：
[code21]
  1. @echo off
  2. for /r d:\test %%i in (.) do echo %%i
  3. pause
复制代码
执行的结果如下所示：
d:\test\.
d:\test\1\.
d:\test\2\.
d:\test\3\.

　　效果就是显示 d:\test 目录及其之下是所有子目录的路径，其效果与 dir /ad /b /s d:\test 类似。若要说到两者的区别，可以归纳出3点：

　　1、for /r 列举出来的路径最后都带有斜杠和点号，而 dir 语句则没有，会对获取到的路径进行进一步加工产生影响；
　　2、for /r 不能列举带隐藏属性的目录，而 dir 语句则可以通过指定 /a 后面紧跟的参数来获取带指定属性的目录，更加灵活；
　　3、若要对获取到的路径进行进一步处理，则需要把 dir 语句放入 for /f 语句中进行分析，写成 for /f %%i in ('dir /ad /b /s') do …… 的形式；由于 for /r 语句是边列举路径边进行处理，所以，在处理大量路径的时候，前期不会感到有停顿，而 for /f 语句则需要等到 dir /ad /b /s 语句把所有路径都列举完之后，再读入内存进行处理，所以，在处理大量路径的时候，前期会感到有明显的停顿。

　　第2点差别很容易被大家忽视，导致用 for /r 列举路径的时候会造成遗漏；而第3点则会让大家有更直观的感受，很容易感觉到两者之间的差别。

　　要是“元素集合”不是点号呢？那又如何？

　　来看看这个代码：
[code22]
  1. @echo off
  2. for /r d:\test %%i in (a b c) do echo %%i
  3. pause
复制代码
运行的结果是：
D:\test\1\a
D:\test\1\b
D:\test\1\c
D:\test\2\a
D:\test\2\b
D:\test\2\c
D:\test\3\a
D:\test\3\b
D:\test\3\c

　　原来，它的含义是：列举 d:\test 及其所有的子目录，对所有的目录路径都分别添加a、b、c之后再显示出来。

　　再来看一个代码：
[code23]
  1. @echo off
  2. for /r d:\test %%i in (*.txt) do echo %%i
  3. pause
复制代码

　　运行结果是：
D:\test\test.txt
D:\test\1\1.txt
D:\test\1\2.txt
D:\test\2\a.txt
D:\test\2\b.txt
D:\test\3\1.txt

　　这段代码的含义是：列举 d:\test 及其所有子目录下的txt文本文件（以.txt结尾的文件夹不会被列出来）。

　　我们再回过头来归纳一下这个语句的作用：
for /r 目录 %%i in (元素集合) do 命令语句集合

　　上面语句的作用是：

　　1、列举“目录”及该目录路径下所有子目录，并把列举出来的目录路径和元素集合中的每一个元素拼接成形如“目录路径\元素”格式的新字符串，然后，对每一条这样的新
字符串执行“命令语句集合”中的每一条命令；
　　特别的是：当“元素集合”带以点号分隔的通配符?或*的时候，把“元素集合”视为文件（不视为文件夹），整条语句的作用是匹配“目录”所指文件夹及其所有子文件夹下
匹配的文件；若不以点号分隔，则把“元素集合”视为文件夹（不视为文件）；
　　2、当省略掉“目录”时，则针对当前目录；
　　3、当元素集合中仅仅是一个点号的时候，将只列举目录路径；

　　（二）for /r 还是 dir /ad /b /s？列举目录时该如何选择

　　前面已经说过，当列举目录时，for /r 和 dir /ad /b /s 的效果是非常类似的，这就产生了一个问题：当我要获取目录路径并进行进一步处理的时候，两者之间，我该如何选择？

　　这个问题，前面其实已经有过一些讨论，现在我们再来作详细的分析。

　　我们来看一下两者各自的优缺点：

　　1、for /r：

　　　　1）优点：

　　　　① 只通过1条语句就可以同时实现获取目录路径和处理目录路径的操作；
　　　　② 遍历文件夹的时候，是边列举边处理的，获取到一条路径就处理一条路径，内存占用小，处理大量路径的时候不会产生停顿感；

　　　　2）缺点： 

　　　　① 不能获取到带隐藏属性的目录，会产生遗漏；
　　　　② 不能获取带指定属性的目录

　　2、dir /ad /s：

　　　　1）优点：

　　　　① 能一次性获取带任意属性的目录，不会产生遗漏；
　　　　② 能通过指定不同的参数获取带任意属性的目录，更具灵活性。

　　　　2）缺点：

　　　　① dir /ad /s 语句仅能获取到目录路径，若要实现进一步的处理，还需要嵌入 for /f 语句中才能实现，写法不够简洁；
　　　　② 嵌入 for /f 语句之后，需要写成 for /f "delims=" %%i in ('dir /ad /b /s') do …… 的格式，受 for /f 语句运行机制的制约，需要先列举完所有的路径放入内存之后，才能对每一条路径进行进一步的处理，处理大量路径时，内存占用量偏大，并且在前期会产生明显的停顿感，用户体验度不够好；

　　综合上述分析，可以做出如下选择：

　　1、若仅仅是为了获取某文件夹及其所有子文件夹的路径的话，请选择 dir /ad /b /s 语句；
　　2、若需要过滤带隐藏属性的文件夹的话，for /r 和 dir 语句都可以实现，但 for /r 内存占用小，处理速度快，是上上之选；
　　3、若需要获取所有文件夹，则除了 dir /ad /b /s 外，别无选择，因为 for /r 语句会遗漏带隐藏属性的文件夹；

　　在实际的使用中，我更喜欢使用 for /f 和 dir 的组合，因为它不会产生遗漏，并能给我带来更灵活的处理方式，唯一需要忍受的，就是它在处理大量路径时前期的停顿感，以及在这背后稍微有点偏高的内存占用；在我追求速度且可以忽略带隐藏属性的目录的时候，我会换用 for /r 的方案，不过这样的情形不多——有谁会愿意为了追求速度而容忍遗漏呢？
 
尺有所短寸有所长，学好批处理没商量；
考虑问题复杂化，解决问题简洁化。
心在天山，身老沧州。
 
 

TOP

   
namejm

荣誉版主

Rank: 8Rank: 8

帖子
1352 
积分
4487 
技术
77  
捐助
501  
注册时间
2007-10-25 
7楼
 
 发表于 2008-10-16 21:11 | 只看该作者
 
 
 
本帖最后由 Hello123World 于 2011-9-18 13:24 编辑

五、仅仅为了匹配第一层目录而存在：for /d

　　for /d 中 /d ，完整的含义是 /directory，本意是为了处理文件夹，它的完整语句应该是这样的：
for /d %%i in (元素集合) do 命令语句集合

　　当“元素集合”中包含有通配符?或*时，它会匹配文件夹，但是，相比 for /r 而言，这个时候的for /d，其作用就小得可怜了：它仅能匹配当前目录下的第一级文件夹，或是指定位置上的文件夹，而不能匹配更深层次的子文件夹。

　　例如：for /d %%i in (d:\test*) do echo %%i 这样的语句 ，会匹配到形如：d:\test、d:\test1、d:\test2之类的文件夹，若不存在这样的路径，将不会有任何回显。

　　当“元素集合”中不包含任何的通配符时，它的作用和 "for %%i in (元素集合) do 命令语句集合" 这样的语句别无二致。

　　因此，for /d 的角色就变得很微妙了：当“元素集合”中包含通配符?或*时，它的作用就是匹配文件夹，此时，它仅能匹配当前目录下的第一级文件夹，或是指定位置上的文件夹，在层次深度上不及 for /r，但和 for /r 一样的坏脾气：不能匹配带隐藏属性的文件夹；在灵活性上不及for /f和dir的组合；当“元素集合”中不包含任何统配符的时候，它完全是 "for %%i in (元素集合) do ……" 语句的翻版，但是又稍显复杂。

　　for /d 的作用是如此有限，我使用的次数是如此之少，以至于我一度找不到它的用武之地，认为它食之无味，弃之可惜，完全是鸡肋一块。

　　某年某月，我在cmd窗口里写下了这样的代码：
[code24]
  1. for /d %i in (test*) do @echo %i
复制代码
我的本意是想查看在我的临时目录下，长年累月的测试工作到底建立了多少测试文件夹，以便我随后把echo换成rd删除之。这个时候，我发现这条代码是如此的简洁，是 for /r 或 for和 dir /ad /b 的组合所无法替代的（echo换成rd就可以直接删除掉这些测试目录）。

　　简洁的代码给我带来的喜悦仅仅持续了短短10几秒的时间，我便开始了迷惘——能用到for /d的类似情形，貌似少之又少且乏善可陈啊。

（hello123world注：正如qzwqzw所言，for /r /d是可以一起使用的；【在for有限的4个参数中，据我所知只有/r /d可以一起使用】。
例如：
  1. @echo off
  2. For /r /d %%i in (*) do echo %%i
  3. pause>nul
复制代码
效果：
显示当前目录下所有的文件夹【包括子文件夹】；等价于 "dir /ad /s /b"。

for /r /d 其实是对 /d 参数的扩展，/d参数本身只能处理第一层文件夹，但是加上/r参数后就可以处理所有的子文件夹；
for /r /d依然不能处理隐藏文件夹。
这里给出使用for /r /d的一般条件：
1.要对文件夹进行操作（dir /ad /s /b可以显示，但不能对文件夹进行操作）；
2.不处理隐藏文件夹（说到底，还是for /f 和dir结合的命令更强大些）。
）
2

评分人数

 
    • Hello123World: 毕竟是2年前的老帖，值得原谅技术 + 1
    • qzwqzw: 如果你知道for /d是可以和/r联用，你还觉得 ...技术 + 1
尺有所短寸有所长，学好批处理没商量；
考虑问题复杂化，解决问题简洁化。
心在天山，身老沧州。
 
 

TOP

   
namejm

荣誉版主

Rank: 8Rank: 8

帖子
1352 
积分
4487 
技术
77  
捐助
501  
注册时间
2007-10-25 
8楼
 
 发表于 2008-10-16 21:11 | 只看该作者
 
 
 
六、计数循环：for /l

　　/l者，/loop的缩写是也，从鸟语翻译过来，loop就是循环的意思。实际上，所有的for语句，都可以看成是一种“循环”，只是在/l中，特指按照指定次数进行循环罢了。

　　for /l 语句的完整格式是这样的：for /l %%i in (x,y,z) do (……)，在这个语句中，x、y和z都只能取整数，正负皆可，x指代起始值，y指代步长，z为终止值，具体含义为：从x开始计数，以y为步长，直至最接近z的那个整数值为止，这之间有多少个数，do后的语句就执行多少次。

　　举个具体的例子：
[code25]
  1. for /l %%i in (1,2,10) do echo bathome
复制代码
在以上的代码中，初始值是1，步长为2，终止值为10，表明计数从1开始，每隔2个数计算一次，直至最接近10的那个整数，罗列出来，就是1,3,5,7,9，再下一个就是11，超过10了，不再计算在内，所以，do后的语句只执行5次，将连续显示5个bathome。

　　实际上，x，y和z的值可正可负，甚至为0，限制非常宽松：

　　1、步长y的值不能为0；
　　2、当步长y的值为正整数时，终止值z不能小于初始值x；
　　3、当步长y的值为负整数的时候，终止值z不能大于初始值x。

　　换而言之，必须保证in和do之间能取到一个有效的数组序列。

　　例如：
[code26]
  1. for /l %%i in (-1,2,5) do echo bathome
复制代码
[code27]
  1. for /l %%i in (5,-2,-1) do echo bathome
复制代码
以上两条代码的功能完全一样，都将显示4次bathome，区别就在于[code26]是正序计算，而[code27]是逆序计数而已。

　　以下几条代码都是有问题的：
[code28]
  1. for /l %%i in (1,0,1) do echo bathome
复制代码
[code29]
  1. for /l %%i in (2,1,1) do echo bathome
复制代码
[code30]
  1. for /l %%i in (1,-1,2) do echo bathome
复制代码
其中，[code28]违反了步长不能为0的限制，将陷入无限循环中；[code29]和[code30]都犯了同样的错误：无法获得有效的数列元素，导致in和do之间取到的值为空元素，从而使得整条for语句无从执行。

　　当大家明白了 for /l 的具体功能之后，是否会想到了与它有异曲同工之妙的goto循环语句呢？似乎，for /l 和 goto 循环语句可以相互替换？

　　一般而言，for /l语句可以换成goto循环，但是，goto循环并不一定能被 for /l 语句替换掉。具体原因，请大家仔细想想，我在此不再详细解说，只是就大家非常关心的一个问题提供一个简洁的答案，那就是：什么时候该用 for /l 计数循环，而什么时候又该用goto条件循环？

　　答案非常简单：当循环次数确定的时候，首选 for /l 语句，也可使用goto语句但不推荐；当循环次数不确定的时候，用goto语句将是唯一的选择，因为，这个时候需要用if之类的条件语句来判断何时结束goto跳转。

[ 本帖最后由 namejm 于 2010-12-25 02:02 编辑 ]
 
尺有所短寸有所长，学好批处理没商量；
考虑问题复杂化，解决问题简洁化。
心在天山，身老沧州。
 
 

TOP

   
namejm

荣誉版主

Rank: 8Rank: 8

帖子
1352 
积分
4487 
技术
77  
捐助
501  
注册时间
2007-10-25 
9楼
 
 发表于 2008-10-16 21:12 | 只看该作者
 
 
 
　　后记：

　　当Windows为我们打开了五彩缤纷的图形窗口的时候
　　DOS命中注定会陨落
　　CMD毫无悬念将萎缩
　　批处理逐渐趋向无声无息
　　而powershell的到来，无疑会让更多的人忘记批处理
　　这是一门即将失传的技艺
　　这是一块行将就木的领域
　　然而，命令行工具仍然具有批量处理一切的巨大威力
　　字符界面仍然是高效操作的代名词
　　曾为批处理的方便灵活而击节赞赏
　　曾被批处理的简洁快速深深折服
　　一直以来，总想为批处理的推广做些什么
　　于是，从在CN-DOS里尽职尽责地为大家解答疑问，到创办了自己的论坛专职答疑解惑，再到无怨无悔地码字写教程，一步步走来，喜怒哀愁，五味杂陈
　　直至如今辞去站长等一切管理职务，逐渐淡出批处理圈子
　　梦依旧在，只是，心有余而力渐有不足
　　这篇从入门到精通的教学帖，从2008年10月开贴到现在，不知不觉拖拖拉拉竟然过去了两年有余
　　每每看到跟帖的会员在问什么时候有更新
　　心中总有一丝愧疚
　　今天，终于抽空对它做个了断
　　只是，年年岁岁花相似，岁岁年年人不同
　　繁杂的事务使我已不再有当初的心境
　　for /l 部分总有虎头蛇尾的感觉
　　只能向各位说声抱歉了
　　在我彻底淡出批处理圈子之前
　　我只能尽我所能地向各位倾我所学了
　　最后，我希望论坛的管理人员能按照顶楼的管理提示经常为这个帖子抽抽水
　　或者是为了大家阅览的方便而永久锁定这个帖子

<转：http://bbs.bathome.net/thread-2189-1-1.html>

转载于:https://www.cnblogs.com/kevin-yuan/p/3641847.html

查看全文
如若内容造成侵权/违法违规/事实不符，请联系编程学习网邮箱：809451989@qq.com进行投诉反馈，一经查实，立即删除！

相关文章

  1. 学习笔记《简明python教程》

    学习笔记《简明python教程》体会：言简意赅，很适合新手入门2018年3月14日21:45:591、global 语句在不使用 global 语句的情况下，不可能为一个定义于函数之外的变量赋值； 如果外面存在全局变量，则将全局变量作用域拿过来； 如果外面不存在这个全局变量，则认为是创建一个全…...

    2024/4/15 9:51:34
  2. Heritrix安装问题处理

    （以下说明是在windows平台操作的） 下载heritrix-1.14.4，解压，修改conf/heritrix.properties, 设置好jmxremote.password相关信息，在bin目录下写个简单的批处理脚本start.bat，用来启动heritrix,内容如下： heritrix.cmd --admin=admin:admin 其中amin:admin为在配置文件中…...

    2024/4/17 21:36:13
  3. Android opengl es 2.0怎么学习

    OpenGLES是一个让人崩溃的东西。在Andorid手机上做3D还就得用它。把我记的一些笔记分享在这里吧：Android OpenGL ES简介 20011-6-3 Android系统使用OpenGL的标准接口来支持3D图形功能，android 3D图形系统也分为java框架和本地代码两部分。 本地代码主要实现的OpenGL接口的库，…...

    2024/4/12 17:21:23
  4. Linux下 python调用讯飞离线语音合成(tts)

    Linux下，使用Python调用讯飞TTS离线SDK，源代码：https://github.com/cch96/iflytek_tts 具体使用方法参照readme解决过程 Windows Windows的SDK有编译好的可以直接被python用ctypes模块调用的动态链接库。可以直接根据科大讯飞的接口文档以及错误码进行开发调试。bin文件夹下…...

    2024/4/18 12:56:52
  5. Python利用 pyinstaller 打包简明教程

    本文首发于我的简书 写在前面 几个月前我分享过一篇基于opencv人脸识别的员工考勤系统,由于我发布在多平台，总共的阅读量快5000+了，这让我备受鼓舞，同时陆陆续续有许多小伙伴联系到我，讨论具体的配置过程，其实过程还蛮复杂的，特别是在pycharm下，所以我打算把这个工程打包…...

    2024/4/18 5:07:49
  6. Android基于XMPP Smack及Openfire学习笔记（1）

    之前开发的项目中有用到IM聊天功能，但是这块功能公司有专门的IM团队来开发，由他们开发好后，直接接入到我们APP中，我参与写IM相关功能非常地少，所以也一直想学习相关知识 。 目前Android主要用的是XMPP协议及OPenfire服务器来实现IM功能，我也从这块入手学习。也感谢所有分…...

    2024/4/13 3:41:06
  7. Heritrix3.3.0源码阅读 动态加载种子

    Heritrix3.3.0有一个很实用的功能，就是在抓取开始之后，依然可以通过在指定目录里放入种子文件的方式向爬虫添加新的种子。接下来，我们就来看看这个功能是怎样实现的。 这个功能是在org.archive.crawler.framework包下的ActionDirectory类实现的，这个类去掉内容后是这个样子…...

    2024/4/9 10:57:43
  8. 【Android语音合成TTS】百度语音接入方法，和使用技巧详解

    请尊重他人的劳动成果，转载请注明出处：【Android语音合成TTS】百度语音接入方法，和使用技巧详解 Ps.依托于百度开放云，百度语音为合作伙伴提供了业界领先、永久免费的语音技术服务，目前已上线的服务包括语音识别、语义解析、语音合成，后续会继续带来开放资源、多轮对话等…...

    2024/4/12 17:21:33
  9. 我爱机器学习网机器学习类别文章汇总

    机器学习领域的几种主要学习方式From Stumps to Trees to ForestsKDD-2014 – The Biggest, Best, and Booming Data Science Meeting前景目标检测1（总结）行人检测5 Tips for Predictive Modeling SuccessSibyl: Google’s system for Large Scale Machine LearningUsing Gra…...

    2024/4/12 17:21:23
  10. 黑马程序员_javaweb(response)

    ----------------------------[url=http://www.itheima.com]android培训[/url]、[url=http://www.itheima.com]java培训[/url]、期待与您交流！----------------------------------response解决中文乱码问题： //更改response的码表,通知服务器用UTF-8码表去取response中的数据…...

    2024/4/12 17:21:38
  11. Python的控制结构(转)

    首先我的工作第一语言是c/c++（面向对象子集）。选择学习python一方面是因为看很多人都说python开发效率高，所以想验证一下；另一方面，Eric S. Raymond在文章：如何成为一名黑客 中对python的推荐。还有一方面，python的设计哲学：用一种方法，最好是只有一种方法来做一件事，…...

    2024/4/12 17:21:43
  12. Heritrix 1.14.3 运行环境配置

    heritrix好像已经有3.0的版本了，但是sourceforge上还是给1.14.3的下载链接，3.0版本的弄不出来，目录结构改动太大了，连heritrix.properties都找不到了，还是用1.14.3来做爬虫吧。 1、下载heritrix-1.14.3-src.zip和heritrix-1.14.3.zip两个压缩包 2、在Eclipse下新建Java项…...

    2024/4/18 5:21:43
  13. Android 入门教程：安装 Android Studio

    原文：Beginning Android Development Tutorial: Installing Android Studio 作者：Megha Bambra 译者：kmyhy更新说明: 本文已更新至 Android Studio 最新版本。由 Megha Bambra 更新。原文作者是 Matt Luedke。之前的更新是 Darryl Bayliss.全球有超过十亿台活跃的设备，因此…...

    2024/4/19 14:44:30
  14. Android实战--语音合成TTS

    接着上一节讨论的问题，本DEMO中会用到TTS语音合成，我们下面介绍一个同样原理的小例子 看一下布局文件很简单：<?xml version="1.0" encoding="utf-8"?> <LinearLayout xmlns:android="http://schemas.android.com/apk/res/android"…...

    2024/4/9 10:57:41
  15. 《JavaWeb视频教程》（p34）

    p34 文件上传及注意问题1. 上传文件a. 引入2个jarapache: commons-fileupload.jar组件commons-fileupload.jar依赖 commons-io.jarb. 代码前台jsp其中,index.jsp<%@ page language="java" contentType="text/html; charset=UTF-8"pageEncoding="UT…...

    2024/4/16 12:00:42
  16. 简明Python3教程 4.安装

    如果你已经安装了Python 2.x，你不需要在安装Python 3.0前卸载Python 2.x。这两者可以共存。 GNU/Linux用户和BSD用户 如果你使用类似于Ubuntu、Fedora、OpenSUSE、Debian、CentOS或其他你选择的GNU/Linux发行版，或类似于FreeBSD的BSD系统，你的系统很可能已经了Python。 可通…...

    2024/4/20 6:08:42
  17. 【转载】heritrix抓取网页信息

    [wbia 1]表示web based information architecture作业1的第1部分，搜索到这篇日志的读者可以直接忽略之。 我对heritrix的了解较浅，希望此文对第一次用爬虫的程序猿有帮助。如果有什么错误请直接留言指正，不胜感激。heritrix是个开源爬虫，可以比较自由的配置爬取过程。herit…...

    2024/4/21 22:46:11
  18. Android学习历程22-Android修改状态栏颜色和标题栏颜色一致

    这个特性是andorid4.4支持的，最少要api19才可以使用。下面介绍一下使用的方法，非常得简单if (Build.VERSION.SDK_INT >= Build.VERSION_CODES.KITKAT) {// 透明状态栏getWindow().addFlags(WindowManager.LayoutParams.FLAG_TRANSLUCENT_STATUS);// 透明导航栏getWindow()…...

    2024/4/18 18:22:01
  19. 7个开源的TTS（文本转语音）系统

    TTS（Text To Speech，文本转语音）是语音合成应用的一种，它将储存于电脑中的文件，如帮助文件或者网页，转换成自然语音输出。TTS可以帮助有视觉障碍的人阅读计算机上的信息，或者只是简单的用来增加文本文档的可读性。TTS经常与声音识别程序一起使用。 本文主要介绍7…...

    2024/4/12 17:22:24
  20. 第一个python小程序

    刚刚开始学习python，花了点时间看了python语法，网上那个python简明教程感觉真不错又结合了一个园友写的系列文章，基本算是把python语法入门了。恰好一个朋友向我抱怨他的一个项目文档乱码问题，就想着用python写一个转换编码的程序来练练手。代码如下：1 #!/usr/bin/python2…...

    2024/4/18 22:44:28

最新文章

  1. Docker容器---Harbor私有仓库部署与管理

    一、搭建本地私有仓库 1、下载registry镜像 [rootlocalhost ~]#docker pull registry Using default tag: latest latest: Pulling from library/registry 79e9f2f55bf5: Pull complete 0d96da54f60b: Pull complete 5b27040df4a2: Pull complete e2ead8259a04: Pull comp…...

    2024/5/2 10:20:44
  2. 梯度消失和梯度爆炸的一些处理方法

    在这里是记录一下梯度消失或梯度爆炸的一些处理技巧。全当学习总结了如有错误还请留言&#xff0c;在此感激不尽。 权重和梯度的更新公式如下&#xff1a; w w − η ⋅ ∇ w w w - \eta \cdot \nabla w ww−η⋅∇w 个人通俗的理解梯度消失就是网络模型在反向求导的时候出…...

    2024/3/20 10:50:27
  3. 鹅厂实习offer

    #转眼已经银四了&#xff0c;你收到offer了吗# 本来都打算四月再投实习了&#xff0c;突然三月初被wxg捞了&#xff08;一年前找日常实习投的简历就更新了下&#xff09;&#xff0c;直接冲了&#xff0c;流程持续二十多天&#xff0c;结果是运气还不错&#xff0c;应该是部门比…...

    2024/5/1 13:19:09
  4. 实景三维在数字乡村建设中的重要作用

    随着科技的飞速发展&#xff0c;数字乡村建设已成为推动乡村振兴、实现农村现代化的重要途径。实景三维技术作为数字乡村建设的重要支撑&#xff0c;正逐渐在各个领域发挥着不可或缺的作用。本文将从实景三维技术在数字乡村中的应用场景、优势及未来展望等方面进行探讨&#xf…...

    2024/5/1 13:46:14
  5. 【外汇早评】美通胀数据走低，美元调整

    原标题：【外汇早评】美通胀数据走低，美元调整昨日美国方面公布了新一期的核心PCE物价指数数据，同比增长1.6%，低于前值和预期值的1.7%，距离美联储的通胀目标2%继续走低，通胀压力较低，且此前美国一季度GDP初值中的消费部分下滑明显，因此市场对美联储后续更可能降息的政策…...

    2024/5/1 17:30:59
  6. 【原油贵金属周评】原油多头拥挤，价格调整

    原标题：【原油贵金属周评】原油多头拥挤，价格调整本周国际劳动节，我们喜迎四天假期，但是整个金融市场确实流动性充沛，大事频发，各个商品波动剧烈。美国方面，在本周四凌晨公布5月份的利率决议和新闻发布会，维持联邦基金利率在2.25%-2.50%不变，符合市场预期。同时美联储…...

    2024/4/30 18:14:14
  7. 【外汇周评】靓丽非农不及疲软通胀影响

    原标题：【外汇周评】靓丽非农不及疲软通胀影响在刚结束的周五，美国方面公布了新一期的非农就业数据，大幅好于前值和预期，新增就业重新回到20万以上。具体数据： 美国4月非农就业人口变动 26.3万人，预期 19万人，前值 19.6万人。 美国4月失业率 3.6%，预期 3.8%，前值 3…...

    2024/4/29 2:29:43
  8. 【原油贵金属早评】库存继续增加，油价收跌

    原标题：【原油贵金属早评】库存继续增加，油价收跌周三清晨公布美国当周API原油库存数据，上周原油库存增加281万桶至4.692亿桶，增幅超过预期的74.4万桶。且有消息人士称，沙特阿美据悉将于6月向亚洲炼油厂额外出售更多原油，印度炼油商预计将每日获得至多20万桶的额外原油供…...

    2024/5/2 9:28:15
  9. 【外汇早评】日本央行会议纪要不改日元强势

    原标题：【外汇早评】日本央行会议纪要不改日元强势近两日日元大幅走强与近期市场风险情绪上升，避险资金回流日元有关，也与前一段时间的美日贸易谈判给日本缓冲期，日本方面对汇率问题也避免继续贬值有关。虽然今日早间日本央行公布的利率会议纪要仍然是支持宽松政策，但这符…...

    2024/4/27 17:58:04
  10. 【原油贵金属早评】欧佩克稳定市场，填补伊朗问题的影响

    原标题：【原油贵金属早评】欧佩克稳定市场，填补伊朗问题的影响近日伊朗局势升温，导致市场担忧影响原油供给，油价试图反弹。此时OPEC表态稳定市场。据消息人士透露，沙特6月石油出口料将低于700万桶/日，沙特已经收到石油消费国提出的6月份扩大出口的“适度要求”，沙特将满…...

    2024/4/27 14:22:49
  11. 【外汇早评】美欲与伊朗重谈协议

    原标题：【外汇早评】美欲与伊朗重谈协议美国对伊朗的制裁遭到伊朗的抗议，昨日伊朗方面提出将部分退出伊核协议。而此行为又遭到欧洲方面对伊朗的谴责和警告，伊朗外长昨日回应称，欧洲国家履行它们的义务，伊核协议就能保证存续。据传闻伊朗的导弹已经对准了以色列和美国的航…...

    2024/4/28 1:28:33
  12. 【原油贵金属早评】波动率飙升，市场情绪动荡

    原标题：【原油贵金属早评】波动率飙升，市场情绪动荡因中美贸易谈判不安情绪影响，金融市场各资产品种出现明显的波动。随着美国与中方开启第十一轮谈判之际，美国按照既定计划向中国2000亿商品征收25%的关税，市场情绪有所平复，已经开始接受这一事实。虽然波动率-恐慌指数VI…...

    2024/4/30 9:43:09
  13. 【原油贵金属周评】伊朗局势升温，黄金多头跃跃欲试

    原标题：【原油贵金属周评】伊朗局势升温，黄金多头跃跃欲试美国和伊朗的局势继续升温，市场风险情绪上升，避险黄金有向上突破阻力的迹象。原油方面稍显平稳，近期美国和OPEC加大供给及市场需求回落的影响，伊朗局势并未推升油价走强。近期中美贸易谈判摩擦再度升级，美国对中…...

    2024/4/27 17:59:30
  14. 【原油贵金属早评】市场情绪继续恶化，黄金上破

    原标题：【原油贵金属早评】市场情绪继续恶化，黄金上破周初中国针对于美国加征关税的进行的反制措施引发市场情绪的大幅波动，人民币汇率出现大幅的贬值动能，金融市场受到非常明显的冲击。尤其是波动率起来之后，对于股市的表现尤其不安。隔夜美国股市出现明显的下行走势，这…...

    2024/4/25 18:39:16
  15. 【外汇早评】美伊僵持，风险情绪继续升温

    原标题：【外汇早评】美伊僵持，风险情绪继续升温昨日沙特两艘油轮再次发生爆炸事件，导致波斯湾局势进一步恶化，市场担忧美伊可能会出现摩擦生火，避险品种获得支撑，黄金和日元大幅走强。美指受中美贸易问题影响而在低位震荡。继5月12日，四艘商船在阿联酋领海附近的阿曼湾、…...

    2024/4/28 1:34:08
  16. 【原油贵金属早评】贸易冲突导致需求低迷，油价弱势

    原标题：【原油贵金属早评】贸易冲突导致需求低迷，油价弱势近日虽然伊朗局势升温，中东地区几起油船被袭击事件影响，但油价并未走高，而是出于调整结构中。由于市场预期局势失控的可能性较低，而中美贸易问题导致的全球经济衰退风险更大，需求会持续低迷，因此油价调整压力较…...

    2024/4/26 19:03:37
  17. 氧生福地 玩美北湖（上）——为时光守候两千年

    原标题：氧生福地 玩美北湖（上）——为时光守候两千年一次说走就走的旅行，只有一张高铁票的距离～ 所以，湖南郴州，我来了～ 从广州南站出发，一个半小时就到达郴州西站了。在动车上，同时改票的南风兄和我居然被分到了一个车厢，所以一路非常愉快地聊了过来。 挺好，最起…...

    2024/4/29 20:46:55
  18. 氧生福地 玩美北湖（中）——永春梯田里的美与鲜

    原标题：氧生福地 玩美北湖（中）——永春梯田里的美与鲜一觉醒来，因为大家太爱“美”照，在柳毅山庄去寻找龙女而错过了早餐时间。近十点，向导坏坏还是带着饥肠辘辘的我们去吃郴州最富有盛名的“鱼头粉”。说这是“十二分推荐”，到郴州必吃的美食之一。 哇塞！那个味美香甜…...

    2024/4/30 22:21:04
  19. 氧生福地 玩美北湖（下）——奔跑吧骚年！

    原标题：氧生福地 玩美北湖（下）——奔跑吧骚年！让我们红尘做伴 活得潇潇洒洒 策马奔腾共享人世繁华 对酒当歌唱出心中喜悦 轰轰烈烈把握青春年华 让我们红尘做伴 活得潇潇洒洒 策马奔腾共享人世繁华 对酒当歌唱出心中喜悦 轰轰烈烈把握青春年华 啊……啊……啊 两…...

    2024/5/1 4:32:01
  20. 扒开伪装医用面膜，翻六倍价格宰客，小姐姐注意了！

    原标题：扒开伪装医用面膜，翻六倍价格宰客，小姐姐注意了！扒开伪装医用面膜，翻六倍价格宰客！当行业里的某一品项火爆了，就会有很多商家蹭热度，装逼忽悠，最近火爆朋友圈的医用面膜，被沾上了污点，到底怎么回事呢？ “比普通面膜安全、效果好！痘痘、痘印、敏感肌都能用…...

    2024/4/27 23:24:42
  21. 「发现」铁皮石斛仙草之神奇功效用于医用面膜

    原标题：「发现」铁皮石斛仙草之神奇功效用于医用面膜丽彦妆铁皮石斛医用面膜|石斛多糖无菌修护补水贴19大优势： 1、铁皮石斛：自唐宋以来，一直被列为皇室贡品，铁皮石斛生于海拔1600米的悬崖峭壁之上，繁殖力差，产量极低，所以古代仅供皇室、贵族享用 2、铁皮石斛自古民间…...

    2024/4/28 5:48:52
  22. 丽彦妆\医用面膜\冷敷贴轻奢医学护肤引导者

    原标题：丽彦妆\医用面膜\冷敷贴轻奢医学护肤引导者【公司简介】 广州华彬企业隶属香港华彬集团有限公司，专注美业21年，其旗下品牌： 「圣茵美」私密荷尔蒙抗衰，产后修复 「圣仪轩」私密荷尔蒙抗衰，产后修复 「花茵莳」私密荷尔蒙抗衰，产后修复 「丽彦妆」专注医学护…...

    2024/4/30 9:42:22
  23. 广州械字号面膜生产厂家OEM/ODM4项须知！

    原标题：广州械字号面膜生产厂家OEM/ODM4项须知！广州械字号面膜生产厂家OEM/ODM流程及注意事项解读： 械字号医用面膜，其实在我国并没有严格的定义，通常我们说的医美面膜指的应该是一种「医用敷料」，也就是说，医用面膜其实算作「医疗器械」的一种，又称「医用冷敷贴」。 …...

    2024/5/2 9:07:46
  24. 械字号医用眼膜缓解用眼过度到底有无作用？

    原标题：械字号医用眼膜缓解用眼过度到底有无作用？医用眼膜/械字号眼膜/医用冷敷眼贴 凝胶层为亲水高分子材料，含70%以上的水分。体表皮肤温度传导到本产品的凝胶层，热量被凝胶内水分子吸收，通过水分的蒸发带走大量的热量，可迅速地降低体表皮肤局部温度，减轻局部皮肤的灼…...

    2024/4/30 9:42:49
  25. 配置失败还原请勿关闭计算机,电脑开机屏幕上面显示，配置失败还原更改 请勿关闭计算机 开不了机 这个问题怎么办...

    解析如下&#xff1a;1、长按电脑电源键直至关机&#xff0c;然后再按一次电源健重启电脑&#xff0c;按F8健进入安全模式2、安全模式下进入Windows系统桌面后&#xff0c;按住“winR”打开运行窗口&#xff0c;输入“services.msc”打开服务设置3、在服务界面&#xff0c;选中…...

    2022/11/19 21:17:18
  26. 错误使用 reshape要执行 RESHAPE，请勿更改元素数目。

    %读入6幅图像&#xff08;每一幅图像的大小是564*564&#xff09; f1 imread(WashingtonDC_Band1_564.tif); subplot(3,2,1),imshow(f1); f2 imread(WashingtonDC_Band2_564.tif); subplot(3,2,2),imshow(f2); f3 imread(WashingtonDC_Band3_564.tif); subplot(3,2,3),imsho…...

    2022/11/19 21:17:16
  27. 配置 已完成 请勿关闭计算机,win7系统关机提示“配置Windows Update已完成30%请勿关闭计算机...

    win7系统关机提示“配置Windows Update已完成30%请勿关闭计算机”问题的解决方法在win7系统关机时如果有升级系统的或者其他需要会直接进入一个 等待界面&#xff0c;在等待界面中我们需要等待操作结束才能关机&#xff0c;虽然这比较麻烦&#xff0c;但是对系统进行配置和升级…...

    2022/11/19 21:17:15
  28. 台式电脑显示配置100%请勿关闭计算机,“准备配置windows 请勿关闭计算机”的解决方法...

    有不少用户在重装Win7系统或更新系统后会遇到“准备配置windows&#xff0c;请勿关闭计算机”的提示&#xff0c;要过很久才能进入系统&#xff0c;有的用户甚至几个小时也无法进入&#xff0c;下面就教大家这个问题的解决方法。第一种方法&#xff1a;我们首先在左下角的“开始…...

    2022/11/19 21:17:14
  29. win7 正在配置 请勿关闭计算机,怎么办Win7开机显示正在配置Windows Update请勿关机...

    置信有很多用户都跟小编一样遇到过这样的问题&#xff0c;电脑时发现开机屏幕显现“正在配置Windows Update&#xff0c;请勿关机”(如下图所示)&#xff0c;而且还需求等大约5分钟才干进入系统。这是怎样回事呢&#xff1f;一切都是正常操作的&#xff0c;为什么开时机呈现“正…...

    2022/11/19 21:17:13
  30. 准备配置windows 请勿关闭计算机 蓝屏,Win7开机总是出现提示“配置Windows请勿关机”...

    Win7系统开机启动时总是出现“配置Windows请勿关机”的提示&#xff0c;没过几秒后电脑自动重启&#xff0c;每次开机都这样无法进入系统&#xff0c;此时碰到这种现象的用户就可以使用以下5种方法解决问题。方法一&#xff1a;开机按下F8&#xff0c;在出现的Windows高级启动选…...

    2022/11/19 21:17:12
  31. 准备windows请勿关闭计算机要多久,windows10系统提示正在准备windows请勿关闭计算机怎么办...

    有不少windows10系统用户反映说碰到这样一个情况&#xff0c;就是电脑提示正在准备windows请勿关闭计算机&#xff0c;碰到这样的问题该怎么解决呢&#xff0c;现在小编就给大家分享一下windows10系统提示正在准备windows请勿关闭计算机的具体第一种方法&#xff1a;1、2、依次…...

    2022/11/19 21:17:11
  32. 配置 已完成 请勿关闭计算机,win7系统关机提示“配置Windows Update已完成30%请勿关闭计算机”的解决方法...

    今天和大家分享一下win7系统重装了Win7旗舰版系统后&#xff0c;每次关机的时候桌面上都会显示一个“配置Windows Update的界面&#xff0c;提示请勿关闭计算机”&#xff0c;每次停留好几分钟才能正常关机&#xff0c;导致什么情况引起的呢&#xff1f;出现配置Windows Update…...

    2022/11/19 21:17:10
  33. 电脑桌面一直是清理请关闭计算机,windows7一直卡在清理 请勿关闭计算机-win7清理请勿关机,win7配置更新35%不动...

    只能是等着&#xff0c;别无他法。说是卡着如果你看硬盘灯应该在读写。如果从 Win 10 无法正常回滚&#xff0c;只能是考虑备份数据后重装系统了。解决来方案一&#xff1a;管理员运行cmd&#xff1a;net stop WuAuServcd %windir%ren SoftwareDistribution SDoldnet start WuA…...

    2022/11/19 21:17:09
  34. 计算机配置更新不起,电脑提示“配置Windows Update请勿关闭计算机”怎么办？

    原标题&#xff1a;电脑提示“配置Windows Update请勿关闭计算机”怎么办&#xff1f;win7系统中在开机与关闭的时候总是显示“配置windows update请勿关闭计算机”相信有不少朋友都曾遇到过一次两次还能忍但经常遇到就叫人感到心烦了遇到这种问题怎么办呢&#xff1f;一般的方…...

    2022/11/19 21:17:08
  35. 计算机正在配置无法关机,关机提示 windows7 正在配置windows 请勿关闭计算机 ，然后等了一晚上也没有关掉。现在电脑无法正常关机...

    关机提示 windows7 正在配置windows 请勿关闭计算机 &#xff0c;然后等了一晚上也没有关掉。现在电脑无法正常关机以下文字资料是由(历史新知网www.lishixinzhi.com)小编为大家搜集整理后发布的内容&#xff0c;让我们赶快一起来看一下吧&#xff01;关机提示 windows7 正在配…...

    2022/11/19 21:17:05
  36. 钉钉提示请勿通过开发者调试模式_钉钉请勿通过开发者调试模式是真的吗好不好用...

    钉钉请勿通过开发者调试模式是真的吗好不好用 更新时间：2020-04-20 22:24:19　浏览次数：729次 区域： 南阳 > 卧龙 列举网提醒您：为保障您的权益，请不要提前支付任何费用！ 虚拟位置外设器!!轨迹模拟&虚拟位置外设神器 专业用于：钉钉，外勤365，红圈通，企业微信和…...

    2022/11/19 21:17:05
  37. 配置失败还原请勿关闭计算机怎么办,win7系统出现“配置windows update失败 还原更改 请勿关闭计算机”，长时间没反应，无法进入系统的解决方案...

    前几天班里有位学生电脑(windows 7系统)出问题了&#xff0c;具体表现是开机时一直停留在“配置windows update失败 还原更改 请勿关闭计算机”这个界面&#xff0c;长时间没反应&#xff0c;无法进入系统。这个问题原来帮其他同学也解决过&#xff0c;网上搜了不少资料&#x…...

    2022/11/19 21:17:04
  38. 一个电脑无法关闭计算机你应该怎么办,电脑显示“清理请勿关闭计算机”怎么办？...

    本文为你提供了3个有效解决电脑显示“清理请勿关闭计算机”问题的方法&#xff0c;并在最后教给你1种保护系统安全的好方法&#xff0c;一起来看看&#xff01;电脑出现“清理请勿关闭计算机”在Windows 7(SP1)和Windows Server 2008 R2 SP1中&#xff0c;添加了1个新功能在“磁…...

    2022/11/19 21:17:03
  39. 请勿关闭计算机还原更改要多久,电脑显示:配置windows更新失败，正在还原更改，请勿关闭计算机怎么办...

    许多用户在长期不使用电脑的时候&#xff0c;开启电脑发现电脑显示&#xff1a;配置windows更新失败&#xff0c;正在还原更改&#xff0c;请勿关闭计算机。。.这要怎么办呢&#xff1f;下面小编就带着大家一起看看吧&#xff01;如果能够正常进入系统&#xff0c;建议您暂时移…...

    2022/11/19 21:17:02
  40. 还原更改请勿关闭计算机 要多久,配置windows update失败 还原更改 请勿关闭计算机，电脑开机后一直显示以...

    配置windows update失败 还原更改 请勿关闭计算机&#xff0c;电脑开机后一直显示以以下文字资料是由(历史新知网www.lishixinzhi.com)小编为大家搜集整理后发布的内容&#xff0c;让我们赶快一起来看一下吧&#xff01;配置windows update失败 还原更改 请勿关闭计算机&#x…...

    2022/11/19 21:17:01
  41. 电脑配置中请勿关闭计算机怎么办,准备配置windows请勿关闭计算机一直显示怎么办【图解】...

    不知道大家有没有遇到过这样的一个问题&#xff0c;就是我们的win7系统在关机的时候&#xff0c;总是喜欢显示“准备配置windows&#xff0c;请勿关机”这样的一个页面&#xff0c;没有什么大碍&#xff0c;但是如果一直等着的话就要两个小时甚至更久都关不了机&#xff0c;非常…...

    2022/11/19 21:17:00
  42. 正在准备配置请勿关闭计算机,正在准备配置windows请勿关闭计算机时间长了解决教程...

    当电脑出现正在准备配置windows请勿关闭计算机时&#xff0c;一般是您正对windows进行升级&#xff0c;但是这个要是长时间没有反应&#xff0c;我们不能再傻等下去了。可能是电脑出了别的问题了&#xff0c;来看看教程的说法。正在准备配置windows请勿关闭计算机时间长了方法一…...

    2022/11/19 21:16:59
  43. 配置失败还原请勿关闭计算机,配置Windows Update失败，还原更改请勿关闭计算机...

    我们使用电脑的过程中有时会遇到这种情况&#xff0c;当我们打开电脑之后&#xff0c;发现一直停留在一个界面&#xff1a;“配置Windows Update失败&#xff0c;还原更改请勿关闭计算机”&#xff0c;等了许久还是无法进入系统。如果我们遇到此类问题应该如何解决呢&#xff0…...

    2022/11/19 21:16:58
  44. 如何在iPhone上关闭“请勿打扰”

    Apple’s “Do Not Disturb While Driving” is a potentially lifesaving iPhone feature, but it doesn’t always turn on automatically at the appropriate time. For example, you might be a passenger in a moving car, but your iPhone may think you’re the one dri…...

    2022/11/19 21:16:57