DDL语句定义

1，创建数据库
2，查询数据库
3，修改数据库
4，删除数据库
5，创建表
6，分区表
7，修改表
8，删除表

1，创建数据库

1）创建一个数据库，数据库在 HDFS 上的默认存储路径是/user/hive/warehouse/*.db。

 hive (default)> create database db_hive; 

2）避免要创建的数据库已经存在错误，增加 if not exists 判断。（标准写法）

 hive (default)> create database db_hive; 

FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. Database db_hive already exists

hive (default)> create database if not exists db_hive; 

3）创建一个数据库，指定数据库在 HDFS 上存放的位置

hive (default)> create database db_hive2 location '/db_hive2.db';

2，查询数据库

1．显示数据库

 hive> show databases;

2．过滤显示查询的数据库

 hive> show databases like 'db_hive*';
OK
database_name
db_hive
db_hive2

3，显示数据库信息

  hive> desc database db_hive; 
db_hive         hdfs://bd001:8020/user/hive/warehouse/db_hive.db        root    USER

4，显示数据库详细信息，extended

 hive> desc database extended db_hive;
OK
db_name comment location        owner_name      owner_type      parameters
db_hive         hdfs://bd001:8020/user/hive/warehouse/db_hive.db        root    USER
Time taken: 0.007 seconds, Fetched: 1 row(s)

5，切换数据库

  hive (default)> use db_hive;

3，修改数据库

用户可以使用 ALTER DATABASE 命令为某个数据库的 DBPROPERTIES 设置键-值对 属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数 据库名和数据库所在的目录位置

hive (db_hive)> alter database db_hive set dbproperties('createtime'='20170830');
OK
Time taken: 0.059 seconds

1，在 hive 中查看修改结果

hive (db_hive)> desc database extended db_hive;
OK
db_name comment location        owner_name      owner_type      parameters
db_hive         hdfs://bd001:8020/user/hive/warehouse/db_hive.db        root    USER    {createtime=20170830}
Time taken: 0.009 seconds, Fetched: 1 row(s)

4，删除数据库

1．删除空数据库

 hive>drop database db_hive2;

2．如果数据库不为空，可以采用 cascade 命令，强制删除

hive> drop database db_hive; FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. InvalidOperationException(message:Database db_hive is not empty. One or more tables exist.) 

hive> drop database db_hive cascade;

5，创建表

建表语法

字段解释说明

（1）CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出 异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。
（2）EXTERNAL 关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际 数据的路径（LOCATION），Hive 创建内部表时，会将数据移动到数据仓库指向的路 径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的 时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。
（3）COMMENT：为表和列添加注释。
(4）PARTITIONED BY 创建分区表
（5）CLUSTERED BY 创建分桶表
（6）SORTED BY 不常用
（7）ROW FORMAT DELIMITED [FIELDS TERMINATED BY char] [COLLECTION ITEMS TERMINATED BY char]
[MAP KEYS TERMINATED BY char]
[LINES TERMINATED BY char] | SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value, property_name=property_value, …)] 用户在建表的时候可以自定义 SerDe 或者使用自带的 SerDe。
如果没有指定 ROW FORMAT 或者 ROW FORMAT DELIMITED，将会使用自带的 SerDe。在建表的时候，用户 还需要为表指定列，用户在指定表的列的同时也会指定自定义的 SerDe，Hive 通过 SerDe 确定表的具体的列的数据。 SerDe 是 Serialize/Deserilize 的简称，目的是用于序列化和反序列化。
（8）STORED AS 指定存储文件类型 常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、 RCFILE（列式存储格式文件） 如果文件数据是纯文本，可以使用 STORED AS TEXTFILE。如果数据需要压缩， 使用 STORED AS SEQUENCEFILE。
（9）LOCATION ：指定表在 HDFS 上的存储位置。
（10）LIKE 允许用户复制现有的表结构，但是不复制数据

管理表（内部表）

Hive 默认情况下会将这些表的数据存储在由配置项 hive.metastore.warehouse.dir(例如，/user/hive/warehouse)所定义的目录的子目录下。当 我 们 删除一个管理表时，Hive 也会删除这个表中数据。管理表不适合和其他工具共享数据。
实操
（1）普通创建表

 create table if not exists student2( id int, name string )row format delimited fields terminated by '\t'stored as textfile location '/user/hive/warehouse/student2'; 

（2）根据查询结果创建表（查询的结果会添加到新创建的表中）

   create table if not exists student3 as select id, name from student; 

（3）根据已经存在的表结构创建表

 create table if not exists student4 like student; 

(4)查看表结构

   hive (default)> desc formatted student2; Table Type: MANAGED_TABLE

外部表

1．理论 因为表是外部表，所以 Hive 并非认为其完全拥有这份数据。删除该表并不会删除掉这 份数据，不过描述表的元数据信息会被删除掉。
2．管理表和外部表的使用场景 每天将收集到的网站日志定期流入 HDFS 文本文件。在外部表（原始日志表）的基础 上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过 SELECT+INSERT 进入内部表
3．案例实操
分别创建部门和员工外部表，并向表中导入数据。
数据自己在系统中定义

创建部门表

create external table if not exists dept( deptno int, dname string, loc int )
row format delimited fields terminated by '\t';

创建员工表

create external table if not exists emp( empno int, ename string, job string)
row format delimited fields terminated by '\t';

向外部表中导入数据 导入数据

load data local inpath '/opt/dept.txt' into table dept;
load data local inpath '/opt/emp.txt' into table emp;

查看表格式化数据

hive (default)> desc formatted dept; Table Type: EXTERNAL_TABLE

管理表与外部表的互相转换

修改内部表 student2 为外部表

alter table student2 set tblproperties('EXTERNAL'='TRUE');

修改外部表 student2 为内部表

 alter table student2 set tblproperties('EXTERNAL'='FALSE');

注意：('EXTERNAL'='TRUE')和('EXTERNAL'='FALSE')为固定写法，区分大小写！

内部表&外部表

未被external修饰的是内部表（managed table），被external修饰的为外部表（external table）；
区别：
内部表数据由Hive自身管理，外部表数据由HDFS管理；
删除内部表会直接删除元数据（metadata）及存储数据；删除外部表仅仅会删除元数据，HDFS上的文件并不会被删除 ，下一次创建表的时候数据会重新加载进来；

6，分区表

分区表实际上就是对应一个 HDFS 文件系统上的独立的文件夹，该文件夹下是该分区 所有的数据文件。Hive 中的分区就是分目录，把一个大的数据集根据业务需要分割成小的 数据集。在查询时通过 WHERE 子句中的表达式选择查询所需要的指定的分区，这样的查询 效率会提高很多

创建分区表语法

 hive (default)>create table dept_partition( deptno int, dname string, loc string )partitioned by (month string) row format delimited fields terminated by '\t';

加载数据到分区表中

load data local inpath '/opt/dept.txt' into table dept_partition partition(month='201709');
load data local inpath '/opt/dept.txt' into table dept_partition partition(month='201708');
load data local inpath '/opt/dept.txt' into table dept_partition partition(month='201707');

查询分区表中数据
单分区查询

   hive (default)> select * from dept_partition where month='201709';

多分区联合查询

select * from dept_partition where month='201709' 
union select * from dept_partition where month='201708' union 
select * from dept_partition where month='201707';

增加分区
创建单个分区

hive (default)> alter table dept_partition add partition(month='201706') ;

同时创建多个分区

  hive (default)> alter table dept_partition add partition(month='201705') partition(month='201704'); 

删除分区 删除单个分区

 hive (default)> alter table dept_partition drop partition (month='201704'); 

同时删除多个分区

   hive (default)> alter table dept_partition drop partition (month='201705'), partition (month='201706');

查看分区表有多少分区

   hive> show partitions dept_partition; 

查看分区表结构

hive> desc formatted dept_partition;   

分区表注意事项

1,创建二级分区表

hive (default)> create table dept_partition2( deptno int, dname string, loc string )
partitioned by (month string, day string) 
row format delimited fields terminated by '\t';

2，加载数据到二级分区表中（可以看他二级分区 又在年份下多了一个目录）

load data local inpath '/opt/dept.txt' 
into table dept_partition2 partition(month='201709', day='13');

3，把数据直接上传到分区目录上，让分区表和数据产生关联的三种方式
方式一：上传数据后修复
创表

     create table dept_partition2( deptno int, dname string, loc string )
partitioned by (month string, day string) 
row format delimited fields terminated by '\t';

上传数据

hdfs dfs -mkdir -p /user/hive/warehouse/db_hive.db/dept_partition2/month=201709/day=12;hdfs dfs -put /opt/dept.txt /user/hive/warehouse/db_hive.db/dept_partition2/month=201709/day=12;

查询数据（查询不到刚上传的数据）

hive (default)> select * from dept_partition2 where month='201709' and day='12';

执行修复命令

hive> msck repair table dept_partition2;

方式二：上传数据后添加分区
上传数据

hdfs dfs -mkdir -p /user/hive/warehouse/db_hive.db/dept_partition2/month=201709/day=11;hdfs dfs -put /opt/dept.txt /user/hive/warehouse/db_hive.db/dept_partition2/month=201709/day=11;

执行添加分区

 hive (default)> alter table dept_partition2 add partition(month='201709', day='11');

查询数据

hive (default)> select * from dept_partition2 where month='201709' and day='11';

方式三：创建文件夹后 load 数据到分区

创建目录

hdfs dfs -mkdir -p /user/hive/warehouse/db_hive.db/dept_partition2/month=201709/day=10;

上传数据

 load data local inpath '/opt/dept.txt' into table dept_partition2 partition(month='201709',day='10');

查询数据

hive (default)> select * from dept_partition2 where month='201709' and day='10';

7，修改表

重命名表
1．语法

 ALTER TABLE table_name RENAME TO new_table_name 

2．实操案例

  hive (default)> alter table dept_partition2 rename to dept_partition3;

增加/修改/替换列信息

（1）查询表结构

 hive> desc dept_partition;

（2）添加列

 hive (default)> alter table dept_partition add columns(deptdesc string); 

（3）查询表结构

 hive> desc dept_partition; 

（4）更新列

  hive (default)> alter table dept_partition change column deptdesc desc int;

（5）查询表结构

 hive> desc dept_partition; 

（6）替换列

  hive (default)> alter table dept_partition replace columns(deptno string, dname string, loc string); 

（7）查询表结构

   hive> desc dept_partition; 

8，删除表

 hive (default)> drop table dept_partition;

看到这了 ，博主也是个刚学完大数据，复习阶段，准备找实习工作，可以先帮兄弟们试试水

欢迎进群闲聊